tstem-9999.ebuild - parlay - yet another gentoo overlay
  HTML git clone https://git.parazyd.org/parlay
   DIR Log
   DIR Files
   DIR Refs
   DIR README
       ---
       tstem-9999.ebuild (1319B)
       ---
            1 # Copyright 2019 Gentoo Authors
            2 # Distributed under the terms of the GNU General Public License v2
            3 
            4 EAPI=6
            5 PYTHON_COMPAT=( python{3_5,3_6,3_7} )
            6 
            7 inherit git-r3 distutils-r1
            8 
            9 DESCRIPTION="Stem is a Python controller library for Tor"
           10 HOMEPAGE="https://stem.torproject.org"
           11 SRC_URI=""
           12 EGIT_REPO_URI="https://git.torproject.org/stem.git"
           13 
           14 LICENSE="LGPL-3"
           15 SLOT="0"
           16 KEYWORDS=""
           17 IUSE="test"
           18 
           19 DEPEND="test? ( dev-python/mock[${PYTHON_USEDEP}]
           20         net-vpn/tor )
           21         dev-python/setuptools[${PYTHON_USEDEP}]"
           22 
           23 RDEPEND="net-vpn/tor"
           24 
           25 DOCS=( docs/{_static,_templates,api,tutorials,{change_log,api,contents,download,faq,index,tutorials}.rst} )
           26 
           27 python_prepare_all() {
           28         # Disable failing test
           29         sed -i -e "/test_expand_path/a \
           30                 \ \ \ \ return" test/integ/util/system.py || die
           31         sed -i -e "/test_parsing_with_example/a \
           32                 \ \ \ \ return" test/unit/manual.py || die
           33         sed -i -e "/test_parsing_with_unknown_options/a \
           34                 \ \ \ \ return" test/unit/manual.py || die
           35         sed -i -e "/test_saving_manual/a \
           36                 \ \ \ \ return" test/unit/manual.py || die
           37         sed -i -e "/test_sdist_matches_git/a \
           38                 \ \ \ \ return" test/integ/installation.py || die
           39         sed -i -e "/test_connections_by_ss/a \
           40                 \ \ \ \ return" test/integ/util/connection.py || die
           41         distutils-r1_python_prepare_all
           42 }
           43 
           44 python_test() {
           45         ${PYTHON} run_tests.py --all --target RUN_ALL || die
           46 }