net-misc/megacmd: Add 9999 ebuild - parlay - yet another gentoo overlay
HTML git clone https://git.parazyd.org/parlay
DIR Log
DIR Files
DIR Refs
DIR README
---
DIR commit a41e7ea1c091c04465b26e713727622633e75f93
DIR parent f9f97bc995615fa956201a9ec23586da5c90a46d
HTML Author: parazyd <parazyd@dyne.org>
Date: Wed, 4 May 2022 19:01:45 +0200
net-misc/megacmd: Add 9999 ebuild
Diffstat:
A net-misc/megacmd/megacmd-9999.ebui… | 49 +++++++++++++++++++++++++++++++
A net-misc/megacmd/metadata.xml | 8 ++++++++
2 files changed, 57 insertions(+), 0 deletions(-)
---
DIR diff --git a/net-misc/megacmd/megacmd-9999.ebuild b/net-misc/megacmd/megacmd-9999.ebuild
@@ -0,0 +1,49 @@
+# Copyright 1999-2021 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+inherit autotools
+if [[ -z ${PV%%*9999} ]]; then
+ inherit git-r3
+ EGIT_REPO_URI="https://github.com/meganz/${PN}.git"
+ EGIT_SUBMODULES=( )
+else
+ PN2="MEGAcmd"
+ SRC_URI="https://yorune.pl/gentoo/${CATEGORY}/${PN}/${PN}-${PV} -> ${P}.tar.gz"
+ S="${WORKDIR}/${PN2}-${PV}_Linux"
+ RESTRICT="primaryuri"
+ KEYWORDS="~amd64 ~x86"
+fi
+
+DESCRIPTION="Command Line Interactive and Scriptable Application to access MEGA"
+HOMEPAGE="https://mega.nz/cmd"
+
+LICENSE="BSD-2"
+SLOT="0"
+DEPEND="
+ >=net-misc/meganz-sdk-3.7.3:=[sodium(+),sqlite]
+ dev-libs/libpcre:3[cxx]
+ sys-libs/readline:0
+"
+RDEPEND="
+ ${DEPEND}
+"
+DOCS=( README.md build/megacmd/megacmd.changes )
+
+src_prepare() {
+ sed \
+ -e '/SUBDIRS.*sdk/d' \
+ -e '/sdk\/m4/d' \
+ -e 's:LMEGAINC=.*:PKG_CHECK_MODULES([MEGA],[libmega])\nLMEGAINC=${MEGA_CFLAGS}:' \
+ -i Makefile.am configure.ac
+ sed \
+ -e 's:\$(top_builddir)/sdk/src/libmega\.la:$(MEGA_LIBS):' \
+ -e 's:mega_cmd_LDADD = .*:&$(MEGA_LIBS):' \
+ -e 's:^mega_exec_CXXFLAGS.*:&\nmega_exec_LDADD=$(MEGA_LIBS):' \
+ -e 's:sdk/include/mega/[^ ]\+\.h::g' \
+ -e '/sdk\/src\/[^ ]\+\.cpp/d' \
+ -i src/include.am
+ default
+ eautoreconf
+}
DIR diff --git a/net-misc/megacmd/metadata.xml b/net-misc/megacmd/metadata.xml
@@ -0,0 +1,8 @@
+<?xml version="1.0" encoding="UTF-8"?>
+<!DOCTYPE pkgmetadata SYSTEM "http://www.gentoo.org/dtd/metadata.dtd">
+<pkgmetadata>
+<maintainer type="person">
+<email>parazyd@dyne.org</email>
+<name>parazyd</name>
+</maintainer>
+</pkgmetadata>