TITLE	CUSTOMIZED BIOS FOR M5B
	LIST	NOCOND
;============================================================================
;
;	ASSEMBLY PARAMETERS
;
;============================================================================
FALSE	EQU	0
TRUE	EQU	NOT FALSE

;============================================================================
;
;	CONDITIONAL ASSEMBLY FLAGS
;
;============================================================================
SHORT	EQU	FALSE		;SHORT BIOS (REMOVES UNESENTIAL CODE)
LSTINC	EQU	FALSE		;LIST INCLUDE FILES
USEMON	EQU	TRUE		;USE MONITOR ROM I/O ROUTINES IF TRUE
INTRPTS	EQU	TRUE		;ENABLE INTERRUPT PROCESSING WHISTLE
INTCPTS	EQU	TRUE		;ENABLE SYSTEM CALL INTERCEPT WHISTLE
BOOT	EQU	10H		;10H: HARD DISK, 3: 8" FLOPPY, 20H: 5" FLOPPY
DEBUG	EQU	FALSE		;TRUE TO DUMP THE IOPB DATA TO PRINTER

	FORM
;****************************************************************************
;
;	CUSTOMIZED BIOS FOR M5B
;	   (c) 1981   GRH Electronics, CUPERTINO, CA
;
;****************************************************************************
;
;	CONFIGURATION:
;
; CPM
; DRIVE	USAGE
   IF	BOOT = 10H		;HARD DISK BOOT CONFIG.
;   A	SIDE 0 & 1 OF HARD DISK PHYSICAL DRIVE 0
;   B	SIDE 2 & 3 OF HARD DISK PHYSICAL DRIVE 0
;   C	SIDE 0 & 1 OF HARD DISK PHYSICAL DRIVE 1
;   D	SIDE 2 & 3 OF HARD DISK PHYSICAL DRIVE 1
;   E	JADE 8" FLOPPY PHYSICAL DRIVE 0
;   F	JADE 8" FLOPPY PHYSICAL DRIVE 1
   ENDIF
   IF	BOOT = 3
;   A	JADE 8" FLOPPY PHYSICAL DRIVE 0
;   B	JADE 8" FLOPPY PHYSICAL DRIVE 1
;   C	SIDE 0 & 1 OF HARD DISK PHYSICAL DRIVE 0
;   D	SIDE 2 & 3 OF HARD DISK PHYSICAL DRIVE 0
;   E	SIDE 0 & 1 OF HARD DISK PHYSICAL DRIVE 1
;   F	SIDE 2 & 3 OF HARD DISK PHYSICAL DRIVE 1
   ENDIF
   IF	BOOT = 20H
;   A	JADE 5" FLOPPY PHYSICAL DRIVE 0
;   B	JADE 5" FLOPPY PHYSICAL DRIVE 1
;   C	SIDE 0 & 1 OF HARD DISK PHYSICAL DRIVE 0
;   D	SIDE 2 & 3 OF HARD DISK PHYSICAL DRIVE 0
;   E	SIDE 0 & 1 OF HARD DISK PHYSICAL DRIVE 1
;   F	SIDE 2 & 3 OF HARD DISK PHYSICAL DRIVE 1
;   G	JADE 8" FLOPPY PHYSICAL DRIVE 0
;   H	JADE 8" FLOPPY PHYSICAL DRIVE 1
   ENDIF
;
;*************************************************************
;   REVISIONS:
;
; 2.2.0 - RELEASE
; 2.2.3 - SWAPPED DCM & BIOS SECTORS ON DISK, ALLOWING A
;	    LARGER BIOS ALLOCATION ON THE DISK.
; 2.2.4 - ADDED NAKED TERMINAL DRIVERS & IOBYTE IN
;	    ANTICIPATION OF THE MONITOR. ALSO, ALL REFERENCES
;	    REQUIRING THE I/O PROMS TO BOOT HAS BEEN REMOVED.
; 2.2.5 - RECONFIGURE FOR 62K SYSTEM.
; 2.2.6 - 20 FEB 83
;	DOUBLE D REV C UPGRADE. CHANGE BOARD STATUS PORT BITS.
; 2.2.7 - 8 MAR 83 GRH
;	ADDED CLOCK/CALENDAR DRIVER, SYSTEM CALL INTERCEPT,
;	ILLEGAL SYSTEM CALL MESSAGE, CHANGED BIOS SIZE TO END
;	OF INITIALIZED DATA AREA. RESTRUCTURE MODULES.
; 2.28 - 22 APR 83   GRH
;	CHANGED DEFINITIONS TO ALLOW BIG DIRECTORIES.
;	DISALLOWED DRIVES C & D.
; 2.29 - 3 SEP 83   GRH
;	Changed Rev # for blocked DCM. Enables IBM system 34
;	256 bytes per sector disks to be read.
; 1.10 - 23 SEP 83   GRH
;	Move clock-calendar routines to ROM. Add Interrupt handler
;	(Mode 2). Change Revision display of sign-on (separate CBIOS rev).
; 2.00 - 24 MAR 84   GRH
;	Modify for hard disk
; 2.01 - 28 APR 84   GRH
;	Change hard disk DPB to reflect half size directory, but keep
;	allocation for 1k directory
; 2.02 - 2 JUN 84   GRH
;	Change floppy disk drivers to relate to ISASI control of JADE
;	   FDC.
;	Change IOPB sector value from physical sector (1..n) to logical
;	   sector value (0..n-1). This maintains more uniformity in
;	   parameter passing between hard disk & JADE floppy IOPBs.
;	Vector I/O routines to monitor rom routines.
; 2.03 - 4 JUN 84   GRH
;	Add bells & whistles again.
;	Move to 61k system.
; 2.04 - 30 MAR 85   GRH
;	Implemented hard disk drive 1 as C: & D:.
;	Implemented the Logon function for the hard disk.
;	Implemented user friendly disk error options: Abort, Retry, Ignore.
;	Solved warm boot hang problem by reseting host adapter if busy.
; 3.00 - 26 JAN 87   GRH
;	Implemented new common IOPB code & Jade floppy firmware support.
;	Implemented disk drive driver tables and new function to return
;	 a ptr to a drive table.
;	Removed init of IOBYTE.
;	Implemented 5" floppy driver.
;	Implemented use of ROM primitives.
;	Moved system down to 60k.
; 3.01 	26 JUN 88 GRH
;	Remove 5" floppy support. Implement in CP/M-86 BIOS.
;	Change single function to return drive table ptr into a BIOS function
;	  call using restart instruction.
;	Change LOGON to specify the ID sector & track. At same time, fix bug
;	  which did not specify the logon track.
; 3.02	7 JUL 88   GRH
;	Add '?' to include file names.
;	Change hard disk system tracks directory reference to new format.
;	Correct bug in drivers which caused retry to fail. (sector remained
;	  corrupted)
;	Stubbed out new Clock routines for present.
; 3.03	31 JUL 88   GRH
;	Unstub Clock routines.
; 3.04	6 AUG 88   GRH
;	Remove floppy side select from BIOS & move to controller.
;	Implement new ID sector format.
;	Implement CP/M 3.0 DPB structure in preparation for deblocking.
; 3.05	11-3-88   GRH
;	Change included data to update IOPB.PBSTAT to new configuration.
; 3.06	1-28-89   GRH
;	Revised primitive calling procedures to use the monitor rom function
;	 rather than swapping Roms itself.
; 3.07	11-25-90   GRH
;	Modify for Ver. 1.22 Monitor.
;	Fix bug in 8" Hard Disk table which benignly (at current level)
;	 caused the drive table to have bad data (default table was missing
;	 the 2 deblocking extension bytes).
;	Implement data xfer inhibit schemes with PB_FLG & PB_BCNT.
;	Add pick-up of THIS_BNK data in all iopb cases.
;	Remove clock buffer set/read system calls.
;	12-5-90  GRH
;	Remove IX IOPB ptr passing to disk drivers.
;	1-13-91   GRH
;	Fix bug which corrupted PB_FLG.
; 3.08	2-22-91   GRH
;	Remove references to THIS_BNK & use monitor function #7 instead.
;	Add track-head shift factor to DPBs for future use.
; 3.09	5-15-91   GRH
;	Change 8" floppy side select to track bit 0. Move calculation from
;	 DCM8 to CBIOS.
;	Remove IOPB ptr passing in IX redundancy.
;	Change DPB track-head shift factor to Sector Offset like track
;	 offset. Disk partitioning will add this value to sector word. It
;	 will be stored in the ID sector data to be dynamic.
;
; 3.10	5-20-91   GRH
;	Change LOGON to attempt to recover from old disks better, using
;	 DCM8301 version controller firmware.
;
VERSN	EQU	310
;
;****************************************************************************


	SUBTTL	SYSTEM DECLARATIONS
;============================================================================
;
; INCLUDE   JDDCONT.DEF
; INCLUDE   COMIOPB3.DEF
; INCLUDE   DISKS3.DEF
; INCLUDE   BDIR.DEF
; INCLUDE   MONBOARD.DEF
; INCLUDE   ISHA.DEF
; INCLUDE B:M5ZF101.DEF
;
;============================================================================
;
	LIST	OFF
*INCLUDE   JDDCONT.DEF
*INCLUDE   COMIOPB3.DEF
*INCLUDE   DISKS3.DEF
*INCLUDE   BDIR.DEF
*INCLUDE   MONBOARD.DEF
*INCLUDE   ISHA.DEF
*INCLUDE B:M5ZF101.DEF
	LIST	ON


;============================================================================
;
;   DISK OPERATING SYSTEM ADDRESSES
;
;============================================================================
;
NKSYS:	EQU	60		;SYSTEM SIZE IN K BYTES
KBYTE:	EQU	1024
CPMSZ:	EQU	KBYTE * NKSYS
CPMBS:	EQU	CPMSZ - (20 * KBYTE) ; CP/M BIAS VALUE
CCP:	EQU	CPMBS + 3400H	;ADDR OF CCP
BDOS:	EQU	CPMBS + 3C00H	;ADDRESS OF BDOS
BIOS:	EQU	CPMBS + 4A00H	;ADDRESS OF BDOS
BIOSR:	EQU	1000H - BIOS
;
;   PAGE 0 LOCATIONS
;
PAGE0:	EQU	0		;START OF CP/M RAM
IOBYTE:	EQU	PAGE0 + 3	;IOBYTE ADDR
DEFDRV:	EQU	PAGE0 + 4	;DEFAULT DRIVE PARAM ADDR
BDOSJV	EQU	PAGE0 + 5	;BDOS SYSTEM CALL ENTRY
THIS_BNK EQU	PAGE0 + 001BH	;BANK # OF THE CURRENT BANK
DK_BDRV	EQU	0041H		;BOOT DRIVE # FROM PROM
DEFBFR	EQU	PAGE0 + 80H	;DEFAULT BUFFER
;
;   BIOS FUNCTION CALL RESTART VECTOR
;
BFUNRST	EQU	28H
BFUNRSV	EQU	PAGE0 + BFUNRST
BFUNRSI	EQU	0C7H + BFUNRST
;
TPA:	EQU	100H


;============================================================================
;
;	OTHER DECLARATIONS
;
;============================================================================
;
MR_RNUM	EQU	0		;INTERIM DEFINITION FOR INTERRUPT ROM SWAP
;
SECSZ:	EQU	128
NDRVS:	EQU	6
   IF	BOOT = 10H
;
;   8" HARD DISK BOOT DATA
;
STHD	EQU	0		;START LOGICAL DRIVE OF HARD DISK
NDHD	EQU	3		;LAST LOGICAL DRIVE OF HARD DISK
ST8FD	EQU	4		;START LOGICAL DRIVE OF 8" FLOPPY
ND8FD	EQU	5		;LAST LOGICAL DRIVE OF 8" FLOPPY
   ENDIF
   IF	BOOT = 3
;
;   8" FLOPPY BOOT DATA
;
STHD	EQU	2		;START LOGICAL DRIVE OF HARD DISK
NDHD	EQU	5		;LAST LOGICAL DRIVE OF HARD DISK
ST8FD	EQU	0		;START LOGICAL DRIVE OF 8" FLOPPY
ND8FD	EQU	1		;LAST LOGICAL DRIVE OF 8" FLOPPY
   ENDIF


;============================================================================
;
;	ASCII CHARS
;
;============================================================================
;
LF:	EQU	0AH
CR:	EQU	0DH
CTRLZ:	EQU	1AH


;@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@
;
;	GENERATE THE TRANSLATION TABLE MACRO
;
;@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@
;
GXLATE	MACRO	#SECTORS, #SKEW
	LIST	OFF
NXTSEC	DL	1		;;START WITH SECTOR 1
LOWEST	DL	1
;;
	REPT	#SECTORS
	LIST	ON
	DB	NXTSEC
	LIST	OFF
NXTSEC	DL	NXTSEC + #SKEW	;ADD SKEW FACTOR
;;
   IF	NXTSEC > #SECTORS	;CHECK FOR OVERFLOW
NXTSEC	DL	NXTSEC - #SECTORS
;;
   IF	NXTSEC <= LOWEST	;CHECK FOR REPEAT
NXTSEC	DL	LOWEST + 1
LOWEST	DL	NXTSEC
   ENDIF
   ENDIF
;;
	ENDM
	LIST	ON
	ENDM


;@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@
;
;	INITIALIZE VERSION TEXT IN RAM MACRO
;
;@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@
;
PVERS	MACRO	#VERS
DD	DL	#VERS
   IF	DD > 9999
	DB	(DD / 10000) + '0'
DD	DL	DD % 10000
   ENDIF
   IF	DD > 999
	DB	(DD / 1000) + '0'
DD	DL	DD % 1000
   ENDIF
	DB	(DD / 100) + '0'
	DB	'.'
	DB	((DD % 100) / 10) + '0'
	DB	(DD % 10) + '0'
	ENDM


	SUBTTL	BIOS CODE
	ORG	BIOS
;----------------------------------------------------------------------------
;
;   BIOS JUMP VECTOR TABLE
;
;----------------------------------------------------------------------------
;
	JP	INIT1		;COLD START ENTRY
	JP	WARM		;RELOAD CCP/BDOS
	JP	CNSCK		;GET CONSOLE STATUS
	JP	CI		;CONSOLE INPUT
	JP	COC		;CONSOLE OUTPUT
	JP	LO		;PRINTER OUTPUT
	JP	PUNCH
	JP	READER
	JP	HOME		;HOME SELECTED DRIVE
	JP	SELDSK		;SELECT DISK DRIVE
	JP	SETTRK		;SET TRACK #
	JP	SETSEC		;SET SECTOR #
	JP	SETDMA		;SET TRANSFER ADDR
	JP	DISKRD		;PERFORM DISK READ
	JP	DISKWR		;PERFORM DISK WRITE
	JP	LISTST		;RETURN LIST STATUS
	JP	SECTRN		;TRANSLATE SECTOR
	JP	BIOFUNC		;EXECUTE FUNCTION CALL


;############################################################################
;
;	THE FOLLOWING BOOT DATA MUST RESIDE AS DEFINED RIGHT BEFORE THE COLD
; INIT ROUTINE START AND MUST BE IN THE 1ST SECTOR. THESE 2 WORDS ARE
; REFERENCED BY THE BOOT LOADER CODE IN ORDER TO DETERMINE THE LOAD ADDRESS
; AND LENGTH OF THE BIOS.
;
;############################################################################
;
	DB	0		;Z80 CPU
	DB	0		;SPARE
BIOSSZ:	DW	BIOSND - BIOS	;BIOS MODULE SIZE IN BYTES
BIOSST:	DW	BIOS		;BIOS MODULE LOAD ADDR FOR SBD
;
;   CONTINUE ON WITH INIT
;
INIT1:	JR	INIT


;############################################################################
;
;	DIRECTORY SECTOR BUFFER STARTS HERE AFTER CRUNCHING COLD START
;  CODE. THIS BUFFER IS USED BY THE CP/M DIRECTORY CHECK ROUTINES THAT
;  CHECK FOR DISK CHANGE.
;
;############################################################################
;
DIRBF:	EQU	$		;BUFFER BEGINNING


;----------------------------------------------------------------------------
;
;    INIT  - COLD START ENTRY FROM BOOT MUST SET ALL BIOS PARAMS
;
;----------------------------------------------------------------------------
;
INIT:
;
;   SET TEMPORARY STACK
;
	LD	SP,DEFBFR	;USE PAGE 0 FOR STACK
;
;   INIT DEFAULT DRIVE
;
	LD	A,(DK_BDRV)	;USE DRIVE # PASSED IN PAGE 0
	AND	A,3
	LD	(DEFDRV),A
;
;   SEND SYSTEM SIGN-ON
;
CLOGO:	LD	HL,MSGSO
	CALL	EDITOR
;
;   MODIFY COLD START VECTOR TO WARM START
;
	LD	HL,(BIOS+4)
	LD	(BIOS+1),HL
;
;   BOOT CCP & BDOS
;
	JR	WARM


;############################################################################
;
;	SIGN-ON MESSAGE
;
;############################################################################
;
MSGSO:	DB	CR,LF
	DB	CPMSZ / (KBYTE * 10) + '0'
	DB	(CPMSZ MOD (KBYTE * 10)) / KBYTE + '0'
	DB	'K CP/M-80  Vers 2.2',CR,LF
	DB	'M5b CBIOS    Vers '
	PVERS	VERSN
	DM	CR,LF


   IF	$ > (DIRBF + SECSZ)
	CONMSG	**** WARNING!  COLD INIT CODE BIGGER THAN DIR BUFFER ****
   ELSE
	DS	DIRBF+SECSZ-$	;FILL OUT DIRECTORY BUFFER TO 1 SECTOR SIZE
   ENDIF


;----------------------------------------------------------
;
;	WARM REBOOT ENTRY LOADS CCP,BDOS FROM DISK &
; SETS UP VARIABLES
;
;----------------------------------------------------------
;
WARM:
;
;   SET TEMPORARY STACK
;
	LD	SP,DEFBFR
  IF	INTRPTS
;
;   SET INTERRUPT VECTOR TABLE BASE
;
	LD	A,HIGH INTABL
	LD	I,A
;
;   SET INTERRUPT MODE TO 2
;
	IM	2
;
;   ENABLE INTERRUPT VECTOR 7
;
	IN	A,(M2_IMASK)
	AND	A,7FH
	OUT	(M2_IMASK),A
;
;   FINALLY ENABLE VECTORED INTERRUPTS
;
	IN	A,(M2_STAT)
	OR	A,M2_IEN
	OUT	(M2_STAT),A
	EI
  ENDIF
;
;   LOG ON DRIVE TO INIT TABLES
;
	LD	A,(DK_BDRV)
	AND	A,3		;MODULO 4
	LD	C,A
	LD	E,0
	CALL	SELDSK
	LD	A,L		;IF ERROR THEN ABORT
	OR	A,H
	JR	Z,WEROR
;
;   READ BOOT DIRECTORY
;

	LD	BC,DEFBFR	;SET XFER ADDRESS (USE DEFAULT BUFFER)
	CALL	SETDMA
;
	LD	BC,BD_SEC	;SET DIRECTORY SECTOR
	CALL	SETSEC
;
	LD	BC,0		;SET TRACK TO 0
	CALL	SETTRK
;
	CALL	DISKRD
	JR	NZ,WEROR
;
;   CHECK FOR VALID BOOT DIRECTORY
;
	LD	A,(DEFBFR)
	CP	A,86H
	JR	C,WEROR
;
;   SET UP TO LOAD CCP/BDOS
;
	LD	HL,(DEFBFR + BD_SBDSS)	;PREFETCH BDOS TRK/SECTOR
	PUSH	HL
;
	LD	HL,(DEFBFR + BD_SCCPS) ;FETCH CCP TRK/SECTOR
	LD	C,L
	LD	B,0
	CALL	SETSEC
;
	LD	C,H
	CALL	SETTRK
;
	LD	BC,CCP
	CALL	SETDMA
;
;   READ CCP/BDOS
;
WREAD:	CALL	DISKRD
	JR	NZ,WEROR	;IF ERROR THEN EXIT
;
;   NEXT SECTOR
;
	LD	HL,BTSEC
	INC	(HL)
;
	LD	DE,(IOPB + PB_BCNTO)	;SECSZ	;DMA := DMA + SECTOR SIZE
	LD	HL,(BTDMA)
	ADD	HL,DE
	LD	(BTDMA),HL
;
;   IF NOT INTO BDOS THEN READ NEXT SECTOR
;
	LD	DE,BDOS
	XOR	A,A
	SBC	HL,DE
	JR	C,WREAD
;
;   ELSE IF AT BEGINNING OF BDOS THEN SET UP NEW TRACK & SECTOR
;
	JR	Z,RDBDOS
;
;   ELSE IF NOT AT BIOS THEN READ NEXT SECTOR
;
	LD	DE,BIOS - BDOS
	SBC	HL,DE
	JP	C,WREAD
;
;   ELSE DONE READING SYSTEM
;
	JP	WZRPG
;
;
;   ELSE SET UP & READ BDOS
;
RDBDOS:	POP	HL		;RESTORE BDOS TRK/SECTOR FROM DIRECTORY
	LD	C,L
	LD	B,A		;A STILL CONTAINS 0
	CALL	SETSEC
;
	LD	C,H
	CALL	SETTRK
;
	JR	WREAD
;
;
;   WARM BOOT ERROR, OUTPUT MSG & HALT
;
WEROR:	LD	HL,MSGLE	;OUTPUT ERROR MESSAGE
	CALL	EDITOR
	HALT
;
;
;   BOOT OK, INIT PAGE 0
;
WZRPG:
;
;   INIT BIOS WARM START IN PAGE 0
;
	LD	A,0C3H
	LD	HL,BIOS + 3
	LD	(PAGE0),A
	LD	(PAGE0 + 1),HL
;
;   INIT BDOS CALL VECTOR IN PAGE 0
;
	LD	HL,BDOS + 6
	LD	(BDOSJV),A
	LD	(BDOSJV + 1),HL
;
;   INIT BIOS CALL VECTOR IN PAGE 0
;
	LD	HL,BIOFUNC
	LD	(BFUNRSV),A
	LD	(BFUNRSV + 1),HL
;
;   SET DEFAULT SECTOR BUFFER
;
	LD	BC,DEFBFR
	CALL	SETDMA
;
  IF	INTCPTS
;
;   PUT BDOS VECTOR INTO INTERCEPT CODE
;
	LD	HL,(BDOS + 7)
	LD	(BDOSV),HL
;
;   NOW PUT INTERCEPT VECTOR INTO BDOS CODE
;
	LD	HL,INTCPT
	LD	(BDOS + 7),HL
;
;   INITIALIZE CLOCK VECTORS IF CLOCK INSTALLED
;
	LD	A,MF_CSYN	;TEST FOR BOARD PRESENT
	CALL	XMROM
;
;   IF CLOCK PRESENT THEN TURN ON CLOCK DRIVE
;
	OR	A,A
	LD	A,38H		;COND. JR (ON)
	JR	Z,CLKON
;
;   ELSE TURN OFF CLOCK DRIVE
;
	LD	A,18H		;UNCOND. JR (OFF) (CAUSES JUMP TO ILLEGAL)
;
CLKON:	LD	(INHCLK),A
;
  ENDIF
;
;   PASS DEFAULT DISK TO CCP
;
	LD	A,(DEFDRV)
	LD	C,A
	JP	CCP

	SUBTTL	BIOS DISK FUNCTION ROUTINES
;++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++
;
;	READ A DISK SECTOR
;	EXIT -	A= 0: OK; /0: ERROR
;
;++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++
;
DISKRD:
;
;   ENABLE UPLOAD (READ DATA)
;
	XOR	A,A
	LD	(BTFLG),A
;
;   DISABLE DOWNLOAD (WRITE DATA)
;
	LD	(IOPB + PB_BCNTO),A
	LD	(IOPB + PB_BCNTO + 1),A
;
;   PASS READ COMMAND
;
	LD	A,PB_READC	;SELECT READ OP
	JP	DISKOP


;++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++
;
;	WRITE A DISK SECTOR
;	EXIT -	A= 0: OK; /0: ERROR
;
;++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++
;
DISKWR:
;
;   DISABLE UPLOAD (READ DATA)
;
	LD	A,1 SHL PB_INHX
	LD	(BTFLG),A
;
;   ENABLE DOWNLOAD (WRITE DATA)
;
	LD	HL,SECSZ
	LD	(IOPB + PB_BCNTO),HL
;
;   PASS WRITE COMMAND
;
	LD	A,PB_WRITC	;SELECT WRITE OP
	JP	DISKOP


;++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++
;
;	SELECT DRIVE FUNCTION
;	LOG-ON - SET DISK PARAMETER BLOCK
;	ENTRY-	C= DRIVE #
;		E= 0 IF NEW SELECT
;	EXIT -	HL= PTR TO DPT OR 0 FOR ERROR
;
;++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++
;
SELDSK:
;
;   ASSUME ERROR
;
	LD	HL,0
;
;   IF UNSUPPORTED DRIVE REQUESTED THEN RETURN 0 (ERROR)
;
	LD	A,C
	CP	A,NDRVS
	RET	NC
;
;   STORE DRIVE # FOR FUTURE USE
;
	LD	(BTDRV),A
;
;   SAVE LOGON REQUEST FLAG
;
	LD	A,E
	LD	(LOGRQ),A
;
;   COMPUTE DISK DRIVER TABLE PTR
;
	CALL	RETDVRT		;DRIVE IS STILL IN C REGISTER
	LD	(DVRTPTR),HL
;
;   PREFETCH DRIVER EXECUTION ADDRESS FROM TABLE
;
	LD	E,(HL)		;STORE ADDRESS
	INC	HL
	LD	D,(HL)
	INC	HL
	LD	(DVRXADR),DE
;
;   FETCH FLAGS
;
	LD	C,(HL)
;
;   COMPUTE DISK PARAMETER TABLE ADDRESS
;
	LD	HL,(BTDRV)
	LD	H,0
	ADD	HL,HL		;DISK # * 16
	ADD	HL,HL
	ADD	HL,HL
	ADD	HL,HL
	LD	DE,D0DPH
	ADD	HL,DE
;
;   IF NOT FIRST SELECT OR LOGON INHIBITED THEN RETURN TABLE PTR
;
	LD	A,(LOGRQ)
	OR	A,C
	CPL
	AND	A,1
	RET	Z
;
;   ELSE LOG ON DRIVE
;
	LD	(DTPTR),HL	;SAVE DRIVE TABLE PTR
;
;   ATTEMPT TO READ ID SECTOR
;
	XOR	A,A		;INIT FLAG BYTE UNTIL FIRMWARE REVISED
	LD	(IOPB + PB_ST2O),A
;
	CALL	DISKLOG
	JP	NZ,FDSKER
;
;   IF NO ID SECTOR THEN USE DEFAULT DPB
;	(NOTE: CONTROLLER HAS SET IT'S DISK DEFAULTS IN DEFBFR IN ALL CASES)
;
	LD	A,(IOPB + PB_ST2O)
	CP	A,-1		;-1:NONE, 0:JADE, 1:DESCRIPTOR, 2: EXTENDED,
;				  3: PARTITIONED, ID
	JR	Z,LGDEF
;
;   ELSE IF OLD FORMATS THEN PAD DPB DATA
;
	CP	A,3
	JR	NC,IDOK
;
	LD	HL,DEFBFR + ID_PSHO	;FILL DATA WITH 0S
	LD	B,ID_FLGO - ID_PSHO
;
PADIDL:	LD	(HL),0
	INC	HL
	DJNZ	PADIDL
;
;   ELSE XFER ID SECTOR DATA TO TABLES
;
IDOK:	CALL	TRNONE		;ASSUME NO TRANSLATION
;
;   IF HARD DISK OR DOUBLE DENSITY THEN NO TRANSLATION
;
	LD	A,(DEFBFR + ID_FLGO)
	AND	A,[1 SHL DF_DTDB] OR [1 SHL DF_HARDB]
;
;   ELSE SET TRANSLATION
;
	CALL	Z,TR8
;
;   XFER DISK DATA TO DPB
;
NOX:	CALL	DPBAD			;GET ADDR OF DPB
	LD	HL,DEFBFR + ID_SPTO
	LD	BC,DPBSZ
	LDIR
;
;   XFER DISK PHYSICAL DATA TO TABLE
;
	LD	HL,DEFBFR + ID_FLGO
;
SEL1:	PUSH	HL
	LD	HL,(DVRTPTR)
	LD	DE,DVRFLG
	ADD	HL,DE
	EX	DE,HL
	POP	HL
	LD	BC,DVRSIZ - DVRFLG
	LDIR
;
;   RETURN DRIVE TABLE PTR
;
	LD	HL,(DTPTR)
	XOR	A,A
	RET
;
;
;   IF NOT HARD DISK THEN GO DO FLOPPY TEST
;
LGDEF:	LD	A,(BTDRV)
   IF	STHD <> 0
	CP	A,STHD
	JR	C,LGCKFD
   ENDIF
	CP	A,NDHD + 1
	JR	NC,LGCKFD
;
;   ELSE USE HARD DISK DEFAULTS
;
	CALL	TRNONE		;  NO XLATE
	LD	HL,HDPBK
;
;   XFER DATA TO TABLES
;
SEL2:	PUSH	HL
	CALL	DPBAD		;  USE DEFAULT TABLE
	POP	HL
	LD	BC,DPBSZ
	LDIR
	JR	SEL1
;
;
;   USE 8" FLOPPY DEFAULTS
;
LGCKFD:	CALL	TR8
	LD	HL,SD8PBK
	JR	SEL2


;****************************************************************************
;
;   HOME DRIVE - TREAT AS SEEK TRK 0
;	EXIT -	BC= 0
;
;****************************************************************************
;
HOME:	LD	BC,0
;
;   FALL INTO SET TRACK
;


;****************************************************************************
;
;	SET TRACK #
;	ENTRY-	BC= TRACK #
;
;****************************************************************************
;
SETTRK:
	LD	(BTTRK),BC
	RET


;****************************************************************************
;
;	SET SECTOR
;	ENTRY-	BC= SECTOR #
;
;****************************************************************************
;
SETSEC:
	LD	(BTSEC),BC
	RET


;****************************************************************************
;
;	SET TRANSFER ADDR
;	ENTRY-	BC= ADDRESS
;	EXIT -	A= ?
;
;****************************************************************************
;
SETDMA:	LD	(BTDMA),BC
	CALL	GETBNK		;FETCH BANK ADDRESS FROM MONITOR
	LD	(BTDMAX),A
	RET


;++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++
;
;	SECTOR TRANSLATION FUNCTION
;	ENTRY-	DE= 0: NO XLATE, ELSE PTR TO XLATE TABLE
;		BC= SECTOR # TO XLATE
;	EXIT -	HL= XLATED SECTOR OR BC + 1
;		BC= UNCHANGED
;		A, DE= ?
;
;++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++
;
SECTRN:
;
;   IF NO TRANSLATION THEN RETURN SECTOR++
;
	LD	A,D	;IF TABLE ADDR = 0 THEN NO TRANSLATION
	OR	A,E
	JP	Z,NOTRAN
;
;   ELSE CALCULATE NEW SECTOR FROM TABLE
;
	EX	DE,HL
	ADD	HL,BC
	LD	L,(HL)
;
	LD	H,0
	RET
;
;
;   CONVERT FROM CP/M'S LOGICAL SECTOR {0..N-1} TO PHYSICAL SECTOR {1..N}
;   
NOTRAN:	LD	HL,1
	ADD	HL,BC
	RET


	SUBTTL	DISK SUPPORT ROUTINES
;++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++
;
;	LOGON DISK FUNCTION
;	EXIT -	A= 0: OK; /0: ERROR
;
;++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++
;
DISKLOG:
;
;   SET DESCRIPTOR SECTOR XFER ADDRESS TO DEFAULT BUFFER
;
	LD	HL,DEFBFR
	LD	(IOPB + PB_DMAO),HL
	CALL	GETBNK
	LD	(IOPB + PB_DMAXO),A
;
;   SET DESCRIPTOR SECTOR SECTOR
;
	LD	HL,ID_SECT
	LD	(IOPB + PB_SECO),HL
;
;   SET DESCRIPTOR SECTOR TRACK
;
	LD	L,H		;H == 0 FROM LAST OPERATION (HL= 0)
	LD	(IOPB + PB_TRKO),HL
;
;   ENABLE UPLOAD
;
	LD	A,L		;L= 0
	LD	(IOPB + PB_FLGO),A
;
;   DISABLE DOWNLOAD
;
	LD	(IOPB + PB_BCNTO),HL
;
;   PASS COMMAND TO EXECUTOR
;
	LD	A,PB_LOGC
	JR	DISKOP2


;++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++
;
;	COMMON DISK I/O CODE
;	ENTRY-	A= IOPB COMMAND
;	EXIT -	A= 0: OK; /0: ERROR
;
;++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++
;
DISKOP:
;
;   SET UP IOPB
;
	LD	HL,BTTRK
	LD	DE,IOPB + PB_TRKO
	LD	BC,PB_BCNTO - PB_TRKO
	LDIR
;
DISKOP2:
	LD	(IOPB + PB_CMDO),A
;
;   FETCH DRIVER VECTOR & EXECUTE DISK DRIVER
;
DKOPLP:
	PUSH	IY		;SAVE IY
	LD	IY,(DVRTPTR)	;FETCH TABLE BASE
;
	LD	HL,DKOPRET	;PUT RETURN ADDRESS ON STACK
	PUSH	HL
;
	LD	HL,(DVRXADR)	;FETCH DRIVER ADDRESS PREFETCHED FROM TABLE
	JP	(HL)
;
;   DRIVER RETURNS HERE
;
DKOPRET:
	POP	IY
;
;   IF NO ERRORS THEN RETURN ZF
;
	RET	Z			;IF NO_ERROR THEN RETURN
;
;   PRINT ERROR
;
	CALL	GETBNK		;SETUP BANK FOR FUTURE COMPATABILITY
	LD	E,A
	LD	HL,IOPB
	LD	A,MF_DIOB	;USE DISPLAY IOPB DATA FUNCTION
	CALL	XMROM
;
;   QUERY USER FOR OPTION
;
	LD	HL,DSKEB
	CALL	EDITOR
;
;   GET USER RESPONSE
;
	CALL	CI		;GET USER RESPONSE
;
	PUSH	AF		;SAVE CHAR
	LD	C,A		;ECHO CHAR
	CALL	COC
	POP	AF
;
	AND	A,5FH		;INSURE UPPER CASE
;
;   IF RETRY THEN RETURN TO CALLER
;
	CP	A,'R'		;IF RETRY THEN RETURN TO CALLER
	JR	Z,DKOPLP
;
;   ELSE IF ABORT THEN DO WARM BOOT
;
	CP	A,'A'		;IF ABORT THEN RE-BOOT
	JP	Z,0
;
;   ELSE IF IGNORE THEN RETURN NO ERROR
;
	SUB	A,'I'		;IF IGNORE THEN RETURN NO ERROR
	RET	Z
;
;   ELSE RETURN ERROR TO BDOS
;
FDSKER:	LD	HL,0		;RETURN DPB_PTR = 0 FOR SELECT FUNCTION
	LD	A,-1		;RETURN -1 TO BDOS
	OR	A,A
	RET


;****************************************************************************
;
;	SET 3740 SECTOR TRANSLATION PROCEDURE
;	ENTRY-	(DTPTR)= MUST BE PTR TO DTP
;	EXIT -	DE, HL= ?
;
;****************************************************************************
;
TR8:
TR3740:	LD	DE,SDTRAN
;
SETTR:	LD	HL,(DTPTR)
	LD	(HL),E
	INC	HL
	LD	(HL),D
	RET


;****************************************************************************
;
;	SET NO SECTOR TRANSLATION PROCEDURE
;	EXIT -	HL, DE= ?
;
;****************************************************************************
;
TRNONE:	LD	DE,0
	JR	SETTR


;++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++
;
;	RETURN DRIVE PARAMETER BLOCK ADDR FUNCTION
;	EXIT -	DE= DPB PTR
;		HL= ?
;
;++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++
;
DPBAD:	LD	HL,(DTPTR)	;FETCH BASE ADDR
	LD	DE,10		;ADD OFFSET OF DPB PTR
	ADD	HL,DE
	LD	E,(HL)		;FETCH DPB PTR
	INC	HL
	LD	D,(HL)
	RET


	SUBTTL	HARD DISK ROUTINES
;++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++
;
;	HARD DISK DRIVER FUNCTION
;	ENTRY-	IY= DRIVER TABLE PTR
;	EXIT -	A= 0: OK; /0: ERROR
;
;++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++
;
HDEXEC:
;
;   CONVERT LOGICAL DRIVE TO PHYSICAL DRIVE
;
	LD	A,(IY + DVRPDRV)	;0,1: DRV 0, 2,3: DRV 1
	LD	(IOPB + PB_DRVO),A
;
;   OFFSET LOGICAL ADDRESS WITH LOGICAL DRIVE
;
	LD	A,(BTDRV)	;IF EVEN THEN ADD 0 ELSE ADD 128
	RRCA
	AND	A,80H
	LD	E,A			;COMPUTE SECTOR
	LD	D,0
	LD	HL,(IOPB + PB_SECO)
;
	PUSH	HL			;SAVE SECTOR TO RESTORE LATER
;
	ADD	HL,DE
	LD	(IOPB + PB_SECO),HL
;
;   EXECUTE IOPB
;
	CALL	XPRIM
;
;   RESTORE SECTOR
;
	POP	HL
	LD	(IOPB + PB_SECO),HL
;
;   DONE
;
	RET



;++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++
;
;	EXECUTE THE IOPB PRIMITIVE
;	EXIT - A= 0: OK, /0: ERROR
;
;++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++
;
XPRIM:
;
;   SET BANK ADDRESS TO THIS BANK FOR NOW
;
	CALL	GETBNK
	LD	E,A		;PRESET IOPB BANK
	LD	(IOPB + PB_DMAXO),A
;
;   EXECUTE THE PRIMITIVE IN ROM
;
	LD	HL,IOPB		;BANKED COMPATABILITY
	LD	DE,(THIS_BNK)
	LD	A,MF_XIOB	;SET MONITOR FUNCTION #
	CALL	XMROM		;EXECUTE THE FUNCTION
;
	OR	A,A		;FUNCTION ERR?
	RET	NZ
;
;   RETURN THE COMMAND RESULTS STATUS
;
	LD	A,(IOPB + PB_STATO)
	OR	A,A
	RET


	SUBTTL	JADE FLOPPY DRIVER ROUTINES
;++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++
;
;	JADE 8" FLOPPY DISK DRIVER FUNCTION
;	ENTRY-	IY= DRIVER TABLE PTR
;	EXIT -	A= 0: OK; /0: ERROR
;
;++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++
;
FD8EXEC:
;
;   CONVERT LOGICAL DRIVE TO PHYSICAL DRIVE
;
	LD	A,(IY + DVRPDRV)
	LD	(IOPB + PB_DRVO),A
;
;   IF HEADS == 1 THEN EXECUTE IOPB
;
	LD	A,(IY + DVRHDS)
	DEC	A
	JP	Z,XPRIM
;
;   ELSE SELECT SIDE FROM TRACK BIT 0
;
	LD	HL,(IOPB + PB_TRKO)
	PUSH	HL			;SAVE FOR ERROR RESTORE
;
	LD	A,(IOPB + PB_SECO +1)	;FETCH SIDE SELECT BYTE
	ADD	A,A			;SHIFT OUT BIT 7
;
	SRL	H			;SHIFT TRACK HIGH BYTE
	RR	L			;ROTATE BIT 8 TO 7 AND 0 TO CF
	RRA				;ROTATE TRACK BIT 0 INTO SECTOR BIT 15
	LD	(IOPB + PB_SECO +1),A
;
	LD	(IOPB + PB_TRKO),HL	;STORE SHIFTED TRACK
;
;   EXECUTE THE IOPB
;
	CALL	XPRIM
;
;   RESTORE THE MODIFIED IOPB SO RETRY WILL WORK
;
	POP	HL			;TRACK
	LD	(IOPB + PB_TRKO),HL
;
	LD	HL,IOPB + PB_SECO +1	;CLEAR BIT 15
	RES	7,(HL)
;
;   DONE
;
	RET


	SUBTTL	BIOS FUNCTION CALLS
;++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++
;
;	FUNCTION DISPATCHER
;	EXIT -	A= -1: ERROR, 0: OK
;
;++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++
;
BIOFUNC:
;
;   IF FUNCTION # NOT IN TABLE THEN RETURN -1
;
	LD	A,C
	CP	A,MAXFUNCS
	LD	A,-1
	RET	NC
;
;   ELSE COMPUTE TABLE ENTRY
;
	PUSH	HL		;SAVE POSSIBLE DATA
;
	LD	HL,BFUNTBL
	LD	A,C
	ADD	A,A
	ADD	A,L
	LD	L,A
	LD	A,0
	ADC	A,H
	LD	H,A
;
;   EXECUTE TABLE ADDRESS
;
	LD	A,(HL)
	INC	HL
	LD	H,(HL)
	LD	L,A
;
	EX	(SP),HL		;PUT CALLER'S DATA IN HL, FUNCTION ADDR ON
	RET			; STACK, EXECUTE FUNCTION ADDRESS ON STACK


;############################################################################
;
;	BIOS FUNCTION TABLE
;
;############################################################################
;
BFUNTBL:
	DW	RETVERS		;0:RETURN VERSION #
	DW	RETDVRTF	;1:RETURN DISK PHYSICAL CONFIGURATION TABLE PTR
	DW	EXIOPB		;2:EXECUTE THE IOPB
MAXFUNCS EQU	($ - BFUNTBL) / 2


;++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++
;
;	RETURN BIOS VERSION #
;	EXIT -	HL= VERSION # IN BINARY {0.00,..655.35}
;
;++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++
;
RETVERS:
	LD	HL,VERSN
	XOR	A,A		;RETURN NO ERROR
	RET
	

;++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++
;
;	RETURN DRIVER TABLE PTR FUNCTION
;	ENTRY-	C= DRIVE # (E FOR FUNCTION CALL)
;	EXIT -	HL= DRIVER TABLE BASE PTR
;		A, C= 0
;
;++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++
;
;   BIOS CALL ENTRY (E= DRIVE #)
;
RETDVRTF:
	LD	C,E
;
RETDVRT:
	LD	HL,DVR0		;START AT 1ST TABLE
;
;   IF DRIVE == 0 THEN ALREADY THERE
;
	LD	A,C
	OR	A,A
	RET	Z
;
;   ELSE IF ILLEGAL DRIVE THEN RETURN ERROR
;
	CP	A,NDRVS
	JR	C,RETDV2
;
	OR	A,A
	RET
;
;
;   ELSE COMPUTE TABLE PTR
;
RETDV2:	LD	B,C
	LD	DE,DVRSIZ
;
RETDVL:	ADD	HL,DE
	DJNZ	RETDVL
;
;   RETURN NO ERROR
;
	XOR	A,A
	RET


;++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++
;
;	EXECUTE IOPB FUNCTION
;	ENTRY-	IX= IOPB PTR
;	EXIT -	A= 0: OK
;
;++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++
;
EXIOPB:
;
;   SET UP FOR CALL
;
	CALL	GETBNK		;E= IOPB PTR IS IN THIS BANK
	LD	E,A
	PUSH	IX		;MAKE HL = IX FOR NOW
	POP	HL
;
	LD	A,MF_XIOB	;MONITOR FUNCTION # (DISK FUNCTION)
	CALL	XMROM		;EXECUTE MONITOR FUNCTION
;
	OR	A,A		;FUNCTION ERROR?
	RET	NZ
;
;   FETCH & RETURN RESULT STATUS
;
	LD	A,(IX + PB_STATO)
	OR	A,A		;TEST RESULT FOR RETURN
	RET


;++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++
;
;	GET BANK NUMBER FUNCTION
;	EXIT -	A= BANK #
;
;++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++
;
GETBNK:
	LD	A,MF_GBNK
	JP	MR_FUN
	

	SUBTTL	NON-DISK PROCEDURES
;****************************************************************************
;
;	OUTPUT HEX DATA TO CONSOLE SUBR
;	ENTRY-	A= DATA
;	EXIT -	A, C= ?
;
;****************************************************************************
;
PRHEX:
	LD	C,A
	LD	A,MF_PHXB
	JP	XMROM


;***************************************************************************
;
;	NEWLINE PROCEDURE
;
;***************************************************************************
;
CRLF:	LD	C,CR
	CALL	COC
	LD	C,LF
	JP	COC


  IF	INTCPTS
	SUBTTL	ADDITIONAL FUNCTIONS TO SUPPORT CDOS PROGRAMS
;***************************************************************************
;
;	SYSTEM CALL INTERCEPT ROUTINE CHECKS FOR ILLEGAL BDOS CALLS &
;  PRINTS MESSAGE IF ILLEGAL. ALSO IMPLEMENTS CDOS CLOCK/CALENDAR
;  SYSTEM CALLS FOR ASMB.
;
;***************************************************************************
INTCPT:	LD	A,C		;CHECK CALL VALIDITY
	CP	A,41		;IF <= 40 THEN OK
;
BDOSV	EQU	$ + 1
	JP	C,BDOS + 11H	;THIS ADDR MODIFIED BY WARM BOOT RTN
;
;  THE FOLLOWING CONDITIONAL JUMP IS MODIFIED TO AN UNCONDITIONAL JUMP BY
;  THE WARM BOOT ROUTINE IF THE CLOCK/CALENDAR BOARD IS NOT PRESENT
;  IF NOT MODIFIED, THEN IT IS ALLWAYS FALSE (NOP).
;
INHCLK:	JR	C,ILLEGC
;
;  NOW CHECK FOR EXTENDED CALLS
;
	CP	A,8DH		;IF RETURN VERSION THEN RETURN IT
	JR	Z,RETCVER
;
	CP	A,90H		;IF NOT CLOCK THEN ERR
	JR	C,ILLEGC
;
	JR	Z,CLKCAL	;IF CALENDAR THEN GET IT
;
	CP	A,92H
	JR	Z,CLKTIM	;IF TIME THEN GET IT
;
;  ILLEGAL SYSTEM CALL
;
ILLEGC:	PUSH	BC		;SAVE FUNCTION #
;
;   OUTPUT WARNING MESSAGE
;
	LD	HL,ISCMSG	;OUTPUT WARNING
	CALL	EDITOR
;
;   OUTPUT FUNCTION #
;
	POP	HL
	LD	A,L
	CALL	PRHEX
;
;   OUTPUT NEW LINE
;
	CALL	CRLF
;
;   RETURN NULLS
;
	XOR	A,A		;BC = HL = A = 0
	LD	L,A
	LD	H,A
	LD	C,A
	LD	B,A
	RET


;++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++
;
;	CDOS RETURN VERSION FUNCTION
;  MAKES CLOCK/CALENDAR WORK.
;	EXIT -	B= 1
;
;++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++
;
RETCVER:
	LD	B,1
	RET

	SUBTTL	CLOCK ROUTINES
;++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++
;
;	RETURN CALENDAR FUNCTION 90H
;	EXIT -	A= DAY
;		B= MONTH
;		C= YEAR
;		L= DAY OF WEEK
;
;++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++
;
CLKCAL:
	LD	A,MF_GCAL
	JR	XMROM


;++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++
;
;	RETURN TIME FUNCTION 92H
;	EXIT -	A= SECONDS
;		B= MINUTES
;		C= HOURS
;
;++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++
;
CLKTIM:
	LD	A,MF_GTIM
	JR	XMROM

   ENDIF

;++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++
;
;	MONITOR ROM EXECUTER
;	ENTRY-	A= FUNCTION #
;
;++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++
;
XMROM:	
;
;   SWITCH TO LOCAL (LARGER) STACK
;
	LD	(SPSAV),SP
	LD	SP,LSTACK
;
;   EXECUTE THE FUNCTION
;
	CALL	MR_FUN		;EXECUTE MONITOR FUNCTION
;
;   RESTORE THE STACK
;
	LD	SP,(SPSAV)
	RET


	SUBTTL	CHAR I/O ROUTINES
;++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++
;
;	CONSOLE INPUT
;	EXIT -	A= CHAR
;
;++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++
;
CI:
	LD	A,MF_CI
	JR	XMROM


;++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++
;
;	RETURN CONSOLE STATUS
;	EXIT -	A= 0: NOT READY
;		   FFH: CHAR READY
;
;++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++
;
CNSCK:
	LD	A,MF_CIS
	JR	XMROM


;****************************************************************************
;
;	CONSOLE OUTPUT
;	ENTRY-	C= CHAR TO OUTPUT
;
;****************************************************************************
;
COC:
	LD	A,MF_CO
	JR	XMROM


;++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++
;
;	READER DRIVER - DUMMY
;	EXIT -	A= CTRL-Z
;
;++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++
;
READER:	LD	A,CTRLZ		;FAKE EOF
;
;   FALL INTO PUNCH RETURN
;


;****************************************************************************
;
;	PUNCH DRIVER
;	ENTRY-	C= CHAR TO OUTPUT
;
;****************************************************************************
;
PUNCH:	RET


;****************************************************************************
;
;	PRINTER DRIVER
;	ENTRY-	C= CHAR TO OUTPUT
;
;****************************************************************************
;
LO:
	LD	A,MF_LO
	JR	XMROM


;++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++
;
;	RETURN LIST DEVICE STATUS
;	EXIT -	A= 0: BUSY, FFH:READY
;
;++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++
;
LISTST:
	LD	A,MF_LOS
	JR	XMROM


;****************************************************************************
;
;	MESSAGE EDITOR
;	ENTRY-	HL= TEXT PTR (BIT 7= 1: TERMINATOR)
;	EXIT -	REGS= ?
;
;****************************************************************************
;
EDITOR:
	CALL	GETBNK
	LD	E,A
	LD	A,MF_PUTS
	JR	XMROM

  IF	INTRPTS
	SUBTTL	INTERRUPTS
;----------------------------------------------------------------------------
;
;	USER INTERRUPT
;
;----------------------------------------------------------------------------
;
ITRAP:
;
;   SAVE REGS FIRST
;
	PUSH	AF
	PUSH	HL
	PUSH	BC
	PUSH	DE
;
;   SAVE CURRENT ROM & GET MONITOR ROM
;
	IN	A,(M2_RSEL)
	LD	(ROMSAV),A
	LD	A,MR_RNUM
	OUT	(M2_RSEL),A
;
;   PRINT PROMPT
;
	LD	HL,ITMSG
IQCONT:
	LD	A,MF_PUTS
	CALL	MR_FUN
;
	LD	HL,IQMSG	;QUERY USER
	LD	A,MF_PUTS
	CALL	MR_FUN
;
;   GET & ECHO USER INPUT
;
	LD	A,MF_CI
	CALL	MR_FUN
;
	PUSH	AF
	LD	C,A
	LD	A,MF_CO
	CALL	MR_FUN
	POP	AF
;
;   IF OPTION IS CTRL-C THEN WARM BOOT
;
	CP	A,3		;IF CTRL-C THEN WARM BOOT
	JP	Z,PAGE0
;
;   IF OPTION IS YES THEN WARM BOOT
;
	AND	A,5FH		;IGNORE CASE
;
	CP	A,'Y'
	JP	Z,PAGE0
;
;   IF OPTION IS INTERRUPT THEN EXECUTE RESTART 7
;
	CP	A,'I'
	JR	NZ,ITRAP1
;
	POP	DE
	POP	BC		;RESTORE REGS 1ST
	POP	HL
	POP	AF
	JP	0038H
;
;
;   IF OPTION IS MONITOR THEN EXECUTE MONITOR BREAKPOINT
;
ITRAP1:	CP	A,'M'
	JR	NZ,ITRAPR
;
	POP	DE
	POP	BC
	POP	HL
	POP	AF
	JP	0008H
;
;
;   ELSE RESTORE REGS & RETURN
;
ITRAPR:
	LD	A,(ROMSAV)	;RESTORE ROM #
	OUT	(M2_RSEL),A
;
	POP	DE
	POP	BC
	POP	HL
	POP	AF
	EI			;RE-ENABLE INTERRUPTS
	RET


;----------------------------------------------------------------------------
;
;	UNSUPPORTED INTERRUPT
;
;----------------------------------------------------------------------------
;
ILLINT:
	PUSH	AF		;SAVE ALL 8080 REGS
	PUSH	HL
	PUSH	BC
	PUSH	DE
	LD	HL,ILLIM	;NOTIFY USER OF INT
	JR	IQCONT


	SUBTTL	INITIALIZED DATA
;############################################################################
;
;	3740 SECTOR TRANSLATION TABLE
;	**** CP/M SINGLE DENSITY ****
;
;############################################################################
;
SDTRAN:	GXLATE	26,6


;############################################################################
;
;	COMMON I/O PARAMETER BLOCK
;
;############################################################################
;
IOPB:	REPT	PB_SIZE
	LIST	OFF
	DB	0
	LIST	ON
	ENDM


;############################################################################
;
;	DISK DRIVER TABLES
;
;############################################################################
;
	STRUCT	0
DVRADD	DS	2	;START ADDRESS OF DISK DRIVER
DVRFG	DS	1	;FLAGS (BIT 0= 1: INHIBIT LOGON)
DVRPDRV	DS	1	;PHYSICAL DRIVE
;DVRLDRV DS	1	;LOGICAL DRIVE {0..N-1}
;
;   THE FOLLOWING MAY BE BROUGHT OFF DISK DESCRIPTOR OR FROM DEFAULT TABLES
;
DVRFLG	DS	1	;DISK FLAGS
DVR0SPT	DS	1	;TRK 0 SECTORS PER TRK
DVR0SZ	DS	1	;TRK 0 SECTOR SIZE
DVR1SPT	DS	1
DVR1SZ	DS	1
DVRDSPT	DS	1
DVRDSZ	DS	1
DVRDTYP	DS	1	;RESERVED FOR DISK TYPE
DVRCYLS	DS	2	;DISK CYLINDERS
DVRHDS	DS	1	;HEADS
;
;   DEFINE THE STRUCTURE SIZE
;
DVRSIZ	DS	0
	ENDM


;@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@
;
;	MACRO TO DEFINE THE DRIVER TABLE RECORD
;	ENTRY-	#DADD= DRIVER ADDRESS
;		#PD= PHYSICAL DRIVE #
;		#FG= DRIVE FLAGS (IDFLGO)
;		#S0= TRK 0 SPT
;		#Z0= TRK 0 SIZE
;		#S1= TRK 1 SPT
;		#Z1= TRK 1 SIZE
;		#SD= DATA TRKS SPT
;		#ZD= DATA TRKS SIZE
;
;@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@
;
ALLDRV	MACRO	#DADD,#PD,#FG,#S0,#Z0,#S1,#Z1,#SD,#ZD,#DT,#CY,#HD
	LIST	ON
	DW	#DADD		;DRIVER EXECUTION ADDR
	DB	0		;LOGON INHIBIT FLAG (LOGON ENABLED)
	DB	#PD		;MONITOR PHYSICAL DRIVE #
	DB	#FG		;DISK FLAGS
	DB	#S0,#Z0		;T0 SECTORS, SIZE
	DB	#S1,#Z1		;T1 SECTORS, SIZE
	DB	#SD,#ZD		;DATA TRKS SECTORS, SIZE
	DB	#DT		;DISK TYPE
	DW	#CY		;CYLS
	DB	#HD		;HEADS
;
	LIST	OFF
	ENDM

   IF	BOOT = 10H
DVR0:	;A
	ALLDRV	HDEXEC,4,60H,32,1,32,1,32,1,10H,256,4
DVR1:	;B
	ALLDRV	HDEXEC,4,60H,32,1,32,1,32,1,10H,256,4
DVR2:	;C
	ALLDRV	HDEXEC,5,60H,32,1,32,1,32,1,10H,256,4
DVR3:	;D
	ALLDRV	HDEXEC,5,60H,32,1,32,1,32,1,10H,256,4
DVR4:	;E
	ALLDRV	FD8EXEC,0,0,26,0,26,0,26,0,0,77,1
DVR5:	;F
	ALLDRV	FD8EXEC,1,0,26,0,26,0,26,0,0,77,1
   ENDIF
   IF	BOOT = 3
DVR0:	;A
	ALLDRV	FD8EXEC,0,0,26,0,26,0,26,0,0,77,1
DVR1:	;B
	ALLDRV	FD8EXEC,1,0,26,0,26,0,26,0,0,77,1
DVR2:	;C
	ALLDRV	HDEXEC,4,60H,32,1,32,1,32,1,10H,256,4
DVR3:	;D
	ALLDRV	HDEXEC,4,60H,32,1,32,1,32,1,10H,256,4
DVR4:	;E
	ALLDRV	HDEXEC,5,60H,32,1,32,1,32,1,10H,256,4
DVR5:	;F
	ALLDRV	HDEXEC,5,60H,32,1,32,1,32,1,10H,256,4
   ENDIF
	LIST	ON


;############################################################################
;
;	DEFAULT 8" FLOPPY DISK PARAMETER BLOCK
;	IBM 3740 SINGLE DENSITY FORMAT
;
;############################################################################
;
SD8PBK:	DW	26		;SECTORS PER TRACK
	DB	3		;BLOCK SHIFT FACTOR
	DB	7		;BLOCK MASK
	DB	0		;NULL MASK
	DW	242		;DISK SIZE -1
	DW	63		;DIRECTORY MAX
	DB	11000000B	;ALLOC 0
	DB	0		;ALLOC 1
	DW	16		;CHECK SIZE
	DW	2		;TRACK OFFSET
	DB	0		;PHYSICAL RECORD SHIFT FACTOR
	DB	0		;PHYSICAL RECORD MASK
	DW	0		;LOGICAL DRIVE SECTOR OFFSET
;
;   DEFAULT DISK PHYSICAL PARAMETERS
;
	DB	0		;FLAGS
	DB	26,0,26,0,26,0	;SECTORS PER TRACK, SECTOR SIZE (128)
	DB	0		;TYPE
	DW	77		;CYLS
	DB	1		;HEADS


;############################################################################
;
;	DEFAULT 8" HARD DISK PARAMETER BLOCK
;
;############################################################################
;
HDPBK:	DW	128		;SECTORS PER TRACK (LOGICAL)	(SPT)
	DB	5		;BLOCK SHIFT FACTOR		(BSH)
	DB	31		;BLOCK MASK			(BLM)
	DB	1		;NULL MASK			(EXM)
	DW	1015		;DISK SIZE (CLUSTERS -1)	(DSM)
	DW	1152 / 2	;DIRECTORY MAX			(DRM)
	DB	0FFH		;ALLOCATION 0			(AL0)
	DB	10000000B	;ALLOCATION 1			(AL1)
	DW	0		;CHECK SIZE			(CKS)
	DW	2		;TRACK OFFSET			(OFF)
	DB	1		;PHYSICAL RECORD SHIFT FACTOR	(PSH)
	DB	1		;PHYSICAL RECORD MASK		(PRM)
	DW	0		;LOGICAL DRIVE SECTOR OFFSET	(SOF)
;
;
;
	DB	01100000B	;FLAGS 256 BPS, HARD, SSSD
	DB	32,1,32,1,32,1	;32 SPT, 256 BPS
	DB	10H		;TYPE
	DW	256		;CYLS
	DB	4		;HEADS


;############################################################################
;
;	MODE 2 INTERRUPT VECTOR TABLE
;
;############################################################################
;
;   START ON AN EVEN PAGE BOUNDARY
;
	IF	$ AND 0FFH
	DS	100H - ($ AND 0FFH)
	ENDIF
INTABL:
	REPT	7		;1ST 7 ARE UNSUPPORTED
	LIST	OFF
	DW	ILLINT
	LIST	ON
	ENDM
;
	DW	ITRAP		;INT 8 IS USER INTERRUPT
  ENDIF


;############################################################################
;
;			MESSAGES
;
;############################################################################
;
MSGLE:	DM	CR,LF,'LOAD ERROR'
;
DSKEB:	DM	CR,LF,'Abort, Ignore, Retry, (BDOS) - '
;
   IF	INTCPTS
ISCMSG:	DM	CR,LF,'ILL SYS CALL, #= '
   ENDIF
   IF	INTRPTS
ITMSG	DM	CR,LF,'User'
ILLIM	DM	CR,LF,'Ill.'
IQMSG	DM	' Int. Abort? (Y/N/I/M) - '
   ENDIF


;############################################################################
;
;	DRIVE PARAMETER HEADER AREA
;	1 PER DRIVE
;
;############################################################################
;
;@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@
;
;	GENERATE A DISK PARAMETER TABLE MACRO
;
;@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@
;
ALLDPH:	MACRO	#D
	LIST	ON
D#D(DD)DPH:			;DRIVE PARAMETER HEADER FOR DRIVE #D(DD)
	DW	0		;;SECTOR TRAN TBL (OR 0 IF NO XLATE)
	DW	0		;;SCRATCH AREA
	DW	0		;;"
	DW	0		;;"
	DW	DIRBF		;;DIRECTORY BUFFER PTR
	DW	D#D(DD)DPB	;;DRIVE PARAMETER BLK PTR
   IF	((DD - 1) <= NDHD) AND ((DD - 1) >= STHD)
	DW	0		;;NO CHECKS ON HARD DISK
   ELSE
	DW	D#D(DD)CHK	;;DRIVE DISK CHECKSUMS ARRAY PTR
   ENDIF
	DW	D#D(DD)ALL	;;DRIVE CLUSTER ALLOCATION BIT MAP PTR
	LIST	OFF
	ENDM
;
;   DEFINE THE DATA
;
DD	DL	1
	REPT	NDRVS
	LIST	OFF
	ALLDPH	0123456789ABCDEF
DD	DL	DD + 1
	LIST	ON
	ENDM

;
;   LAST OF INITIALIZED CODE READ FROM DISK
;
BIOSND	EQU	$

	SUBTTL	UNINITIALIZED DATA AREA
;############################################################################
;
;   THE FOLLOWING DATA MUST RESIDE IN THIS ORDER TO MATCH THE IOPB DATA
;
;############################################################################
;
BTDRV:	DS	1	;DRIVE #
BTTRK	DS	2	;TRACK #
BTSEC	DS	2	;SECTOR #
BTFLG	DS	1	;RESERVED FOR FLAGS
BTDMA	DS	2	;DMA ADDRESS
BTDMAX	DS	1	;DMA EXTENDED ADDRESS


;############################################################################
;
;   VARIABLES
;
;############################################################################
;
DTPTR:	DS	2	;DRIVE TABLE PTR
LOGRQ:	DS	1	;LOG ON REQUEST REG.
DVRTPTR	DS	2	;DRIVE DRIVER TABLE BASE ADDRESS PTR
DVRXADR	DS	2	;DRIVE DRIVER EXECUTION ADDRESS
SECOFF	DS	2	;LOGICAL DRIVE SECTOR OFFSET (ADD TO SECTOR)
;
ROMSAV	EQU	0048H	;DS	1	;ROM SWAP SAVE OF ORIGINAL ROM
SPSAV	DS	2	;USER SP SAVE WHILE USING LOCAL STACK
	DS	64	;LOCAL STACK (32 ENTRIES)
LSTACK	EQU	$


;############################################################################
;
;   DRIVE ALLOCATION AREAS
;
;############################################################################
;
;@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@
;
;	MACRO TO DEFINE THE DRIVE ALLOCATION & CHECKSUMS AREA
;
;@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@
;
ALLDAL:	MACRO	#D
	LIST	ON
   IF	((DD - 1) >= STHD) AND ((DD - 1) <= NDHD)
D#D(DD)ALL:	DS	127	;ALLOCATION BIT MAP FOR 8" HARD DRIVE #D(DD)
   ENDIF
   IF	((DD - 1) >= ST8FD) AND ((DD - 1) <= ND8FD)
D#D(DD)ALL:	DS	57	;ALLOCATION BIT MAP FOR 8" DRIVE #D(DD)
D#D(DD)CHK	DS	32    ;DIRECTORY CHECKSUMS STORAGE (1 BYTE PER SECTOR)
   ENDIF
	LIST	OFF
	ENDM
;
;   RESERVE THE DATA SPACE
;
DD	DL	1
	REPT	NDRVS
	LIST	OFF
	ALLDAL	0123456789ABCDEF
DD	DL	DD + 1
	LIST	ON
	ENDM


;############################################################################
;
;   RESERVE DRIVE PARAMETER BLOCKS
;
;############################################################################
;
	STRUCT	0
DPBSPT	DS	2	;SPT- SECTORS/TRACK
DPBBSH	DS	1	;BSH- BLOCK SHIFT FACTOR DETERMINED BY CLUSTER SIZE
			;	1K= 3, 2K= 4, 4K= 5, 8K= 6, 16K= 7
DPBBLM	DS	1	;BLM- BLOCK MASK
			;	1K = 7, 2K= 15, 4K= 31, 8K= 63, 16K= 127
DPBEXM	DS	1	;EXM- EXTENT MASK
			;	DSM < 256 : 1K= 0, 2K= 1, 4K= 3, 8K= 7, 16K= 15
			;	DSM > 255 : 2K= 0, 4K= 1, 8K= 3, 16K= 7
DPBDSM	DS	2	;DSM- DRIVE STORAGE SIZE (IN CLUSTERS)
	;  INT(((#_TRACKS - OFF) * SPT * BYTES PER SECTOR) / CLUSTER SIZE) -1
DPBDRM	DS	2	;DRM- DIRECTORY SIZE -1
DPBAL0	DS	2	;AL0,1- DIRECTORY ALLOCATION
			;	1 MSB PER DIRECTORY CLUSTER ALLOCATED
DPBCKS	DS	2	;CKS- # DIRECTORY SECTORS CHECKED
			;	(DRM +1) / 4
DPBOFF	DS	2	;OFF- # RESERVED TRACKS (USUALLY 2)
;
;   ADDITIONAL CP/M 3.0 DATA (ALSO COULD BE USED BY CP/M 2.2 DEBLOCKING)
;
DPBPSH	DS	1	;PSH- PHYSICAL RECORD SHIFT FACTOR BASED ON BYTES/SEC
			;	0: 128, 1: 256, 2: 512, 3: 1024
DPBPHM	DS	1	;PHM- PHYSICAL RECORD MASK BASED ON BYTES/SEC
			;	0: 128, 1: 256, 3: 512, 7: 1024
;
;   ADDITIONAL DISK PARTITIONING DATA FOR THE LOGICAL DRIVE SELECTION.
;	PARTITIONING BY TRACKS ARE IMPLIMENTED THRU BDOS USING DPBOFF ABOVE.
;	PARTITIONING BY HEADS ARE IMPLIMENTED BY USING THE FOLLOWING DATA.
;	  (HEAD BITS ARE INCLUDED IN SECTOR WORD UPPER BITS)
;
DPBSOF DS	2	;SOF- SECTOR OFFSET (FOR LOGICAL DRIVE)
;				0: NONE, 1..65535: OFFSET
DPBSZ	DS	0
	ENDM
;
;
;@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@
;
;	GENERATE THE DPB FOR DRIVE MACRO
;
;@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@
;
ALLDPB:	MACRO	#D
	LIST	ON
D#D(DD)DPB:	DS	DPBSZ		;ALLOCATION FOR DRIVE #D(DD)
	LIST	OFF
	ENDM
;
;   RESERVE THE DATA SPACE
;
DD	DL	1
	REPT	NDRVS
	LIST	OFF
	ALLDPB	0123456789ABCDEF
DD	DL	DD + 1
	LIST	ON
	ENDM


   IF	(($ - 8000H) > 07700H) OR ($ < 8000H)
	CONMSG	**** BIOS TOO BIG, USE MOVCPM & RE-ADJUST! ****
   ENDIF

	END