TITLE	CUSTOMIZED BIOS FOR M5B
	LIST	NOCOND
;*************************************************************
;
;   (c) 1981   GRH Electronics, CUPERTINO, CA
;
;*************************************************************
;
;	CONFIGURATION:
;
; CPM	ISASI
; DRIVE	DRIVE	USAGE
;   A	  0	SIDE 0 & 1 OF HARD DISK PHYSICAL DRIVE 0
;   B	  1	SIDE 2 & 3 OF HARD DISK PHYSICAL DRIVE 0
;	  2	SASI CONTROLLER FLOPPY DRIVE 1
;	  3	NOT USED
;   C	  4	JADE FLOPPY PHYSICAL DRIVE 0
;   D	  5	JADE FLOPPY PHYSICAL DRIVE 1
;   	  6	JADE FLOPPY PHYSICAL DRIVE 2
;   	  7	JADE FLOPPY PHYSICAL DRIVE 3
;
;*************************************************************
;   REVISIONS:
;
; 2.2.0 - RELEASE
;
; 2.2.3 - SWAPPED DCM & BIOS SECTORS ON DISK, ALLOWING A
;	    LARGER BIOS ALLOCATION ON THE DISK.
;
; 2.2.4 - ADDED NAKED TERMINAL DRIVERS & IOBYTE IN
;	    ANTICIPATION OF THE MONITOR. ALSO, ALL REFERENCES
;	    REQUIRING THE I/O PROMS TO BOOT HAS BEEN REMOVED.
;
; 2.2.5 - RECONFIGURE FOR 62K SYSTEM.
;
; 2.2.6 - 20 FEB 83
;	DOUBLE D REV C UPGRADE. CHANGE BOARD STATUS PORT BITS.
;
; 2.2.7 - 8 MAR 83 GRH
;	ADDED CLOCK/CALENDAR DRIVER, SYSTEM CALL INTERCEPT,
;	ILLEGAL SYSTEM CALL MESSAGE, CHANGED BIOS SIZE TO END
;	OF INITIALIZED DATA AREA. RESTRUCTURE MODULES.
;
; 2.28 - 22 APR 83   GRH
;	CHANGED DEFINITIONS TO ALLOW BIG DIRECTORIES.
;	DISALLOWED DRIVES C & D.
;
; 2.29 - 3 SEP 83   GRH
;	Changed Rev # for blocked DCM. Enables IBM system 34
;	256 bytes per sector disks to be read.
;
; 1.10 - 23 SEP 83   GRH
;	Move clock-calendar routines to ROM. Add Interrupt handler
;	(Mode 2). Change Revision display of sign-on (separate CBIOS rev).
;
; 2.00 - 24 MAR 84   GRH
;	Modify for hard disk
;
; 2.01 - 28 APR 84   GRH
;	Change hard disk DPB to reflect half size directory, but keep
;	allocation for 1k directory
;
; 2.02 - 2 JUN 84   GRH
;	Change floppy disk drivers to relate to ISASI control of JADE
;	   FDC.
;	Change IOPB sector value from physical sector (1..n) to logical
;	   sector value (0..n-1). This maintains more uniformity in
;	   parameter passing between hard disk & JADE floppy IOPBs.
;	Vector I/O routines to monitor rom routines.
;
; 2.03 - 4 JUN 84   GRH
;	Add bells & whistles again.
;	Move to 61k system.
;
VERSN	EQU	'03'
;
;*************************************************************************

	SUBTTL	SYSTEM DECLARATIONS
FALSE	EQU	0
TRUE	EQU	NOT FALSE

;
;	CONDITIONAL ASSEMBLY FLAGS
;
SHORT	EQU	TRUE		;SHORT BIOS (REMOVES UNESENTIAL CODE)
LSTINC	EQU	FALSE		;LIST INCLUDE FILES
HARDBT	EQU	TRUE		;HARD DISK BOOT (FALSE= FLOPPY BOOT)
USEMON	EQU	TRUE		;USE MONITOR ROM I/O ROUTINES IF TRUE
INTRPTS	EQU	TRUE		;ENABLE INTERRUPT PROCESSING WHISTLE
INTCPTS	EQU	TRUE		;ENABLE SYSTEM CALL INTERCEPT WHISTLE

;--------------------------------------
;
;   DISK OPERATING SYSTEM ADDRESSES
;
;--------------------------------------
NKSYS:	EQU	61		;SYSTEM SIZE IN K BYTES
KBYTE:	EQU	1024
CPMSZ:	EQU	KBYTE*NKSYS
CPMBS:	EQU	CPMSZ - (20 * KBYTE) ; CP/M BIAS VALUE
CCP:	EQU	CPMBS+3400H	;ADDR OF CCP
BDOS:	EQU	CPMBS+3C00H	;ADDRESS OF BDOS
BIOS:	EQU	CPMBS+4A00H	;ADDRESS OF BDOS
BIOSR:	EQU	1000H-BIOS
;
PAGE0:	EQU	0		;START OF CP/M RAM
IOBYTE:	EQU	PAGE0 + 3	;IOBYTE ADDR
DEFDRV:	EQU	PAGE0 + 4	;DEFAULT DRIVE PARAM ADDR
DEFBFR	EQU	PAGE0 + 80H	;DEFAULT BUFFER
TPA:	EQU	100H

;
;	OTHER DECLARATIONS
;
DEFIOB:	EQU	80H		;INITIAL IOBYTE VALUE (LPT ON)
DFDRV:	EQU	0		;INITIAL DEFAULT DRIVE
SECSZ:	EQU	128
FMTSZ:	EQU	100H		;FORMAT BUFFER SIZE
NDRVS:	EQU	4
BTDIRS	EQU	3		;HARD DISK SYSTEM TRACKS DIRECTORY SECTOR
BTCCPO	EQU	3		;OFFSET TO CCP ENTRY IN SYS TRKS DIRECTORY
	IF	HARDBT
LASTSEC	EQU	47		;LAST BOOT SECTOR
	ELSE
LASTSEC	EQU	45		;LAST BOOT SECTOR
	ENDIF

;*************************************************************************
;
;	THE FOLLOWING 2 PARAMETERS MUST REFLECT THE MAX DISK SIZE &
; THE MAX DIRECTORY SIZE.
;
;*************************************************************************
ALLSIZ	EQU	33	;ALLOCATION BIT MAP SIZE (1 BYTE PER 8 CLUSTERS)
CHKSIZ	EQU	32	;DIRECTORY CHECKSUMS ARRAY SIZE (1 BYTE PER DIR. SECTOR)

;****************************
;
;	ADDRESSES
;
;****************************
CALROM	EQU	7		;CALENDAR ROM SELECT #
RDBENT	EQU	0F800H		;READ CLOCK BUFFER ENTRY
SETENT	EQU	RDBENT + 3	;SET CLOCK ENTRY
CALENT	EQU	RDBENT + 6	;RETURN CALENDAR ENTRY
TIMENT	EQU	RDBENT + 9	;RETURN TIME ENTRY


;****************************
;
;	ASCII CHARS
;
;****************************
LF:	EQU	0AH
CR:	EQU	0DH
CTRLZ:	EQU	1AH

;
; INCLUDE	JDDCONT.DEF
; INCLUDE	MONBOARD.DEF
; INCLUDE	IOBOARD.DEF
; INCLUDE	NAKEDT.DEF
; INCLUDE	ISASI.DEF
; INCLUDE	CLOCK.DEF

	IF	NOT LSTINC
	LIST	OFF
	ENDIF
*INCLUDE	JDDCONT.DEF
*INCLUDE	MONBOARD.DEF
*INCLUDE	IOBOARD.DEF
*INCLUDE	NAKEDT.DEF
*INCLUDE	ISASI.DEF
*INCLUDE	CLOCK.DEF

	LIST	ON
	SUBTTL	BIOS CODE
	ORG	BIOS
;----------------------------
;
;   BIOS JUMP VECTOR TABLE
;
;----------------------------
	JP	INIT1		;COLD START ENTRY
	JP	WARM		;RELOAD CCP/BDOS
	JP	CNSCK		;GET CONSOLE STATUS
	JP	CI		;CONSOLE INPUT
	JP	COC		;CONSOLE OUTPUT
	JP	LO		;PRINTER OUTPUT
	JP	PUNCH
	JP	READER
	JP	HOME		;HOME SELECTED DRIVE
	JP	SELDSK		;SELECT DISK DRIVE
	JP	SETTRK		;SET TRACK #
	JP	SETSEC		;SET SECTOR #
	JP	SETDMA		;SET TRANSFER ADDR
	JP	DISKRD		;PERFORM DISK READ
	JP	DISKWR		;PERFORM DISK WRITE
	JP	LISTST		;RETURN LIST STATUS
	JP	SECTRN		;TRANSLATE SECTOR
	RET			;FORMAT DUMMY

;**************************************************************************
;
;	THESE BOOT PARAMS MUST RESIDE AS DEFINED RIGHT BEFORE THE COLD
;  INIT ROUTINE START AND MUST BE IN THE 1ST SECTOR.
;  THESE 2 WORDS ARE REFERENCED BY THE BOOT CODE IN
;  ORDER TO FIND THE LOAD ADDRESS FOR THE BIOS & IT'S LENGTH.
;
;**************************************************************************
BIOSSZ:	DW	BIOSND - BIOS	;BIOS MODULE SIZE IN BYTES
BIOSST:	DW	BIOS		;BIOS MODULE LOAD ADDR FOR SBD
INIT1:	JR	INIT

;--------------------------------------
;
;   RESERVE DRIVE PARAMETER BLOCKS
;
;--------------------------------------

D0DPB:	DS	2	;SPT- SECTORS/TRACK
	DS	1	;BSH- BLOCK SHIFT FACTOR DETERMINED BY CLUSTER SIZE
			;	1K= 3, 2K= 4, 4K= 5, 8K= 6, 16K= 7
	DS	1	;BLM- BLOCK MASK
			;	1K = 7, 2K= 15, 4K= 31, 8K= 63, 16K= 127
	DS	1	;EXM- EXTENT MASK
			;	DSM < 256 : 1K= 0, 2K= 1, 4K= 3, 8K= 7, 16K= 15
			;	DSM > 255 : 2K= 0, 4K= 1, 8K= 3, 16K= 7
	DS	2	;DSM- DRIVE STORAGE SIZE (IN CLUSTERS)
	;  INT(((#_TRACKS - OFF) * SPT * BYTES PER SECTOR) / CLUSTER SIZE) -1
	DS	2	;DRM- DIRECTORY SIZE -1
	DS	2	;AL0,1- DIRECTORY ALLOCATION
			;	1 MSB PER DIRECTORY CLUSTER ALLOCATED
	DS	2	;CKS- # DIRECTORY SECTORS CHECKED
			;	(DRM +1) / 4
	DS	2	;OFF- # RESERVED TRACKS (USUALLY 2)

DPBSZ	EQU	$ - D0DPB
	IF	NDRVS GT 3
D1DPB:	DS	DPBSZ
	ENDIF
	IF	NDRVS GT 4
D2DPB:	DS	DPBSZ
	ENDIF
	IF	NDRVS GT 5
D3DPB:	DS	DPBSZ
	ENDIF


;----------------------------------
;
;  DISK CONTROLLER COMMAND BLOCK
;
;----------------------------------
BTDRV:	DB	0		;DRIVE #
BTTRK:	DB	0		;TRACK #
BTSEC:	DB	0		;SECTOR #


;--------------------------------------
;
;	OTHER BIOS VARS NEEDING INIT
;
;--------------------------------------
BTDMA:	DW	0		;SYSTEM TRANSFER ADDR
DTPTR:	DW	0		;DRIVE TABLE PTR
LOGRQ:	DB	0		;LOG ON REQUEST REG.


;--------------------------------------------------------------------------
;
;	DIRECTORY SECTOR BUFFER STARTS HERE AFTER CRUNCHING COLD START
;  CODE. THIS BUFFER IS USED BY THE CP/M DIRECTORY CHECK ROUTINES THAT
;  CHECK FOR DISK CHANGE.
;
;--------------------------------------------------------------------------
DIRBF:	EQU	$		;BUFFER BEGINNING


;--------------------------------------------------------------------
;
;    INIT  - COLD START ENTRY FROM BOOT MUST SET ALL BIOS PARAMS
;
;--------------------------------------------------------------------
INIT:
	LD	SP,DEFBFR	;USE PAGE 0 FOR STACK

	CALL	GETMON		;MAKE SURE BOOT ROM IS DISABLED

	LD	A,DEFIOB	;INIT I/O BYTE
	LD	(IOBYTE),A

	LD	A,DFDRV		;INIT DEFAULT DRIVE
	LD	(DEFDRV),A
;
;   SEND SYSTEM SIGN-ON
;
CLOGO:	LD	HL,MSGSO
	CALL	EDITOR

	LD	HL,(BIOS+4)	;MODIFY COLD START TO WARM START
	LD	(BIOS+1),HL
	JP	WARM

;
;	SIGN-ON MESSAGE
;
MSGSO:	DB	CR,LF
	DB	CPMSZ / (KBYTE * 10) + '0'
	DB	(CPMSZ MOD (KBYTE * 10)) / KBYTE + '0'
	DB	'K CP/M-80  Vers 2.2',CR,LF
	DB	'M5b CBIOS    Vers 2.'
	DB	HIGH VERSN , LOW VERSN,CR,LF,0


	DS	DIRBF+SECSZ-$	;FILL OUT DIRECTORY BUFFER TO 1 SECTOR SIZE


;----------------------------------------------------------
;
;	WARM REBOOT ENTRY LOADS CCP,BDOS FROM DISK &
; SETS UP VARIABLES
;
;----------------------------------------------------------
WARM:
  IF	INTRPTS
	LD	A,HIGH INTABL	;INIT INTERRUPT VECTORS
	LD	I,A
	IM	2		;USE MODE 2

	IN	A,INTMSK
	AND	7FH		;ENABLE INT 7
	OUT	INTMSK,A

	IN	A,MONSTS	;ENABLE MONITOR BOARD INTERRUPTS
	OR	MONIE
	OUT	MONSTS,A
	EI
  ENDIF

	LD	SP,DEFBFR	;SELECT TEMPORARY STACK

	CALL	GETMON		;SELECT MONITOR ROM

	LD	A,0		;SET DRIVE 0
	LD	(BTDRV),A

   IF	HARDBT
	LD	BC,DEFBFR	;READ BOOT DIRECTORY
	CALL	SETDMA
	LD	C,BTDIRS
	CALL	SETSEC
	LD	C,0
   ELSE
	LD	C,1
   ENDIF
	CALL	SETTRK

   IF	HARDBT
	CALL	DISKRD
	JR	NZ,WEROR
   ENDIF

	LD	BC,CCP		;SET LOAD ADDR
	CALL	SETDMA

   IF	HARDBT
	LD	A,(DEFBFR + BTCCPO) ;PICK UP START OF CP/M IMAGE FROM DIRECTORY
	INC	A		;OFFSET FOR READ DECRIMENT
	LD	C,A
   ELSE
	LD	C,2		;START WITH SECTOR #2
   ENDIF
	CALL	SETSEC

;   READ CCP/BDOS

WREAD:	CALL	DISKRD
	JR	NZ,WEROR	;IF ERROR THEN EXIT

	LD	A,(BTSEC)	;IF LAST SECTOR THEN DONE
	CP	LASTSEC
	JR	NC,WZRPG

	INC	A		;NEXT SECTOR
	LD	(BTSEC),A
	LD	DE,SECSZ	;DMA := DMA + SECTOR SIZE
	LD	HL,(BTDMA)
	ADD	HL,DE
	LD	(BTDMA),HL
	JR	WREAD

;   WARM BOOT ERROR, OUTPUT MSG & HALT

WEROR:	LD	HL,MSGLE	;OUTPUT ERROR MESSAGE
	CALL	EDITOR
	HALT

;   BOOT OK, INIT PAGE 0

WZRPG:	LD	A,0C3H		;INITIALIZE BIOS WARM START VECTOR
	LD	HL,BIOS + 3
	LD	(PAGE0),A
	LD	(PAGE0 + 1),HL

	LD	HL,BDOS + 6	;INIT BDOS CALL VECTOR
	LD	(PAGE0 + 5),A
	LD	(PAGE0 + 6),HL

	LD	HL,DEFBFR	;SET DEFAULT SECTOR BUFFER
	LD	(BTDMA),HL

  IF	INTCPTS
	LD	HL,(BDOS + 7)	;GET BDOS VECTOR
	LD	(BDOSV),HL	;PUT IN INTERCEPT CODE
	LD	HL,INTCPT	;NOW PUT INTERCEPT VECTOR INTO BDOS VECTOR
	LD	(BDOS + 7),HL

	IN	A,(CLKDAT)    ;IF CLOCK NOT PRESENT THEN TURN OFF CLOCK DRIVE
	AND	11000000B      ;TEST UNUSED BUT DRIVEN BITS (1S IF NOT THERE)
	LD	A,38H		;COND. JR (ON)
	JR	Z,CLKON
	LD	A,18H		;UNCOND. JR (OFF) (CAUSES JUMP TO ILLEGAL)
CLKON:	LD	(INHCLK),A
  ENDIF

	LD	A,(DEFDRV)	;PASS IN DEFAULT DISK TO CCP
	LD	C,A
	JP	CCP

	SUBTTL	DISK ROUTINES
;***************************
;
;   READ A DISK SECTOR
;
;***************************
DISKRD:
	LD	IY,IOPB		;SELECT READ OP
	LD	(IY + PBCMD),RDCMD
	JR	HDDO


;****************************
;
;   WRITE A DISK SECTOR
;
;****************************
DISKWR:
	LD	IY,IOPB			;SELECT WRITE OP
	LD	(IY + PBCMD),WRCMD

HDDO:	LD	A,(BTDRV)
	CP	2
   IF	HARDBT
	JR	NC,DOFLOP
   ELSE
	JR	C,DOFLOP
   ENDIF

	LD	(IY + PBDRV),0		;ONLY USE HARD DISK FOR NOW

   IF	NOT HARDBT
	SUB	2			;BIAS DOWN TO HARD DISK ADDRESS
   ENDIF

	LD	D,0			;COMPUTE SECTOR
	RRCA
	RR	D
	LD	A,(BTSEC)
	DEC	A			;CHANGE TO LOGICAL SECTOR
	AND	7FH
	OR	D
RWOPC:	LD	(IY + PBSEC),A

	LD	A,(BTTRK)		;SET TRACK
	LD	(IY + PBTRK),A

	LD	(IY + PBFLG),0		;NO FLAGS FOR NOW

	LD	HL,(BTDMA)		;SET DMA ADDR
	LD	(IY + PBDMA),L
	LD	(IY + [PBDMA + 1]),H
	LD	(IY + PBDMAX),0		;THIS BANK FOR NOW

	CALL	HDEXEC			; DO OP
	JR	NZ,DSKER		;EXIT IF ERROR

;-----------------------------------------
;
;	NORMAL EXIT
;	EXIT -	A= 0
;
;-----------------------------------------
DSKOK:	XOR	A		;RETURN 0
	RET


DOFLOP:
   IF	HARDBT
	ADD	2
   ELSE
	ADD	4			;ADD OFFSET TO JADE VECTORS
   ENDIF
	LD	(IY + PBDRV),A
	LD	A,(BTSEC)
	DEC	A			;CHANGE TO LOGICAL SECTOR
	JR	RWOPC


;----------------------------------
;
;	DISK ERROR EXIT
;	EXIT -	A= FFH
;
;----------------------------------
DSKER:	LD	A,0FFH		;RETURN -1
	OR	A
	RET


;*************************************************
;
;	SELECT DRIVE 
;	LOG-ON - SET DISK PARAMETER BLOCK
;	ENTRY-	C= DRIVE #
;		E= 0 IF NEVER LOGGED BEFORE
;	EXIT -	HL= PTR TO DPT OR 0 FOR ERROR
;
;*************************************************
SELDSK:	LD	HL,0		;ASSUME ERROR

	LD	A,C		;SET DRIVE #
	CP	NDRVS		;IF NOT 0..3 THEN ERROR
	RET	NC

	LD	(BTDRV),A
	CP	2
   IF	HARDBT
	JR	NC,FDSEL
   ELSE
	JR	C,FDSEL
   ENDIF

   IF	HARDBT
	OR	A		;IF LOGICAL DRIVE 0 THEN RETURN DPB 0
   ELSE
	SUB	A,2		;IF LOGICAL DRIVE 0 THEN RETURN DPB 0
   ENDIF
	LD	HL,HDDPH0	;FIXED DATA
	RET	Z
	LD	HL,HDDPH1	;ELSE RETURN DPB 1
	RET

FDSEL:
	LD	A,E		;SET LOG REQUEST VECTOR
	LD	(LOGRQ),A

RETDSK:	LD	A,(BTDRV)	;COMPUTE TABLE PTR
   IF	HARDBT
	SUB	2
   ENDIF
	LD	L,A
	LD	H,0
	ADD	HL,HL		;DISK # * 16
	ADD	HL,HL
	ADD	HL,HL
	ADD	HL,HL
	LD	DE,D0DPH
	ADD	HL,DE

	LD	A,(LOGRQ)	;RETURN TABLE PTR IF NOT 1ST LOG-ON
	AND	1
	JR	NZ,DSKOK

;  READ IDENTITY SECTOR

	LD	(DTPTR),HL	;SAVE DRIVE TABLE PTR

	LD	A,(BTDRV)	;PERFORM DCM LOG-ON
   IF	HARDBT
	ADD	2		;BIAS UP TO FDC DRIVES
   ELSE
	ADD	4		;BIAS UP TO FDC DRIVES
   ENDIF
	LD	(LOGIOPB + PBDRV),A
	CALL	HDEXECL
	JR	Z,LOGCK

	LD	HL,0		;ERROR- BAD LOG-ON
	JR	DSKER

;  CHECK FOR JADE ID

LOGCK:	
	LD	HL,DEFBFR
	LD	DE,JADEID
	LD	B,IDSZE

LOGID:	LD	A,(DE)	;IF NO MATCH THEN ASSUME 3740 FORMAT
	CP	(HL)
	JR	NZ,LG3740

	INC	HL
	INC	DE
	DJNZ	LOGID

;   DISKETTE CONTAINS ID. SET NO SECTOR TRANSLATION

	XOR	A
	LD	HL,(DTPTR)	;FETCH BASE ADDR
	LD	(HL),A		;XLATE TABLE PTR = 0
	INC	HL
	LD	(HL),A

	CALL	DPBAD		;GET ADDR OF DPB & MOVE DOWN DISK INFO TO IT
	LD	HL,DEFBFR + DDDPB - DDBUF
	LD	BC,DPBSZ
	LDIR

	LD	A,(DEFBFR + DDDDF - DDBUF) ;IF DENSITY FLAG = 0 THEN USE 3740
	AND	4
	CALL	Z,TR3740

	LD	HL,(DTPTR)	;ELSE RETURN PTR TO TABLE
	JP	DSKOK

;   ASSUME 3740 FORMAT DISKETTE

LG3740:	CALL	TR3740		;SET SECTOR TRANSLATE

	CALL	DPBAD		;MOVE PARAMETERS INTO DISK PAR BLK
	LD	BC,DPBSZ
	LD	HL,SDPBK
	LDIR

	LD	HL,(DTPTR)	;RETURN PTR TO TABLE
	JP	DSKOK


;*********************************
;
;   SET 3740 SECTOR TRANSLATION
;
;*********************************
TR3740:	LD	DE,SDTRAN
	LD	HL,(DTPTR)
	LD	(HL),E
	INC	HL
	LD	(HL),D
	RET


;**************************************
;
;   GET DRIVE PARAMETER BLOCK ADDR
;	EXIT -	DE= DPB PTR
;		HL= ?
;
;**************************************
DPBAD:	LD	HL,(DTPTR)	;FETCH BASE ADDR
	LD	DE,10		;ADD OFFSET OF DPB PTR
	ADD	HL,DE
	LD	E,(HL)		;FETCH DPB PTR
	INC	HL
	LD	D,(HL)
	RET


;***************************************
;
;   HOME DRIVE - TREAT AS SEEK TRK 0
;
;***************************************
HOME:	LD	C,0


;*****************************
;
;	SET TRACK #
;	ENTRY-	C= TRACK #
;	EXIT -	A= C= TRACK #
;
;*****************************
SETTRK:	LD	A,C
	LD	(BTTRK),A
	RET


;*****************************
;
;	SET SECTOR
;	ENTRY-	C= SECTOR #
;	EXIT -	A= C= SECTOR #
;
;*****************************
SETSEC:	LD	A,C
	LD	(BTSEC),A
	RET


;*****************************
;
;	SET TRANSFER ADDR
;	ENTRY-	BC= ADDRESS
;	EXIT -	HL= BC= ADDRESS
;
;*****************************
SETDMA:	LD	(BTDMA),BC
	RET


;***************************************************************
;
;	SECTOR TRANSLATION
;	ENTRY-	DE= 0: NO XLATE, ELSE PTR TO XLATE TABLE
;		BC= SECTOR # TO XLATE
;	EXIT -	HL= XLATED SECTOR OR (BC) + 1
;		BC= UNCHANGED
;		A, DE= ?
;
;***************************************************************
SECTRN:	LD	A,D	;IF TABLE ADDR = 0 THEN NO TRANSLATION
	OR	E
	JR	Z,NOTRAN

	EX	DE,HL
	ADD	HL,BC
	LD	L,(HL)

	LD	H,0
	RET
;
NOTRAN:	LD	HL,1
	ADD	HL,BC
	RET

;*********************************
;
;	HARD DISK EXECUTE SUBR
;	EXIT -	NZ= ERRORS
;
;*********************************
HDEXECL:
	LD	HL,LIOPBAD	;USE LOGON IOPB
	JR	HDEXEC1

HDEXEC:
	LD	HL,IOPBADR	;OUTPUT IOPB ADDRESS TO ISASI
HDEXEC1:
	LD	B,3

HDX1:	LD	A,(HL)
	INC	HL
	OUT	(HDATA),A
	LD	A,(HL)
	INC	HL
	OUT	(HCMD),A

HDX2:	IN	A,(HSTATUS)
	BIT	HBUSYB,A
	JR	NZ,HDX2

	DJNZ	HDX1

	LD	A,HEXEC		;NOW EXECUTE THE IOPB
	OUT	(HCMD),A

HDX3:	IN	A,(HSTATUS)
	BIT	HBUSYB,A
	JR	NZ,HDX3

	AND	(1 SHL HERRB) + (1 SHL HFERRB)	;CHECK FOR ERRORS
	RET

  IF	INTCPTS

;***************************************************************************
;
;	SYSTEM CALL INTERCEPT ROUTINE CHECKS FOR ILLEGAL BDOS CALLS &
;  PRINTS MESSAGE IF ILLEGAL. ALSO IMPLEMENTS CDOS CLOCK/CALENDAR
;  SYSTEM CALLS FOR ASMB.
;
;***************************************************************************
INTCPT:	LD	A,C		;CHECK CALL VALIDITY
	CP	41		;IF <= 40 THEN OK

BDOSV	EQU	$ + 1
	JP	C,BDOS + 11H	;THIS ADDR MODIFIED BY WARM BOOT RTN
;
;  THE FOLLOWING CONDITIONAL JUMP IS MODIFIED TO AN UNCONDITIONAL JUMP BY
;  THE WARM BOOT ROUTINE IF THE CLOCK/CALENDAR BOARD IS NOT PRESENT
;  IF NOT MODIFIED, THEN IT IS ALLWAYS FALSE (NOP).
;
INHCLK:	JR	C,ILLEGC
;
;  NOW CHECK FOR EXTENDED CALLS
;
	CP	8DH		;IF RETURN VERSION THEN RETURN IT
	JR	Z,RETVER

	CP	90H		;IF NOT CLOCK THEN ERR
	JR	C,ILLEGC

	JR	Z,CLKCAL	;IF CALENDAR THEN GET IT

	CP	92H
	JR	C,CLKSET	;IF SET FUNCTION THEN SET CLOCK

	JR	Z,CLKTIM	;IF TIME THEN GET IT

	CP	93H
	JR	Z,CLKRDC	;IF READ CLOCK THEN GET IT
;
;  ILLEGAL SYSTEM CALL
;
ILLEGC:	LD	HL,ISCMSG	;OUTPUT WARNING
	CALL	EDITOR
	LD	L,A		;BC = HL = A = 0
	LD	H,A
	LD	C,A
	LD	B,A
	RET


;*****************************************
;
;	CDOS RETURN VERSION SYSTEM CALL
;  MAKES CLOCK/CALENDAR WORK.
;	EXIT -	B= 1
;
;*****************************************
RETVER:	LD	B,1
	RET

	SUBTTL	MISC I/O DRIVERS
;*****************************************
;
;	CLOCK ROUTINES
;
;*****************************************
;
;	RETURN CALENDAR FUNCTION 90H
;	EXIT -	A= DAY
;		B= MONTH
;		C= YEAR
;		L= DAY OF WEEK
;
;*****************************************
CLKCAL:
	LD	HL,CALENT	;ROM ENTRY POINT

CLK1:	LD	BC,CLKBFR	;READ CLOCK
	JR	CLK2


;*************************************
;
;	RETURN TIME FUNCTION 92H
;	EXIT -	A= SECONDS
;		B= MINITS
;		C= HOURS
;
;*************************************
CLKTIM:
	LD	HL,TIMENT
	JR	CLK1


;************************************************************
;
;	READ CLOCK TIME FUNCTION 93H
;	ENTRY-	DE= PTR TO 13 BYTE BUFFER FOR CLOCK DATA
;
;************************************************************
CLKRDC:
	LD	C,E		;SET UP PARAMETERS
	LD	B,D
	LD	HL,RDBENT
	JR	CLK2


;**********************************************************
;
;	CLOCK SET FUNCTION 91H
;	ENTRY-	DE= CLOCK IMAGE BUFR PTR (13 BYTES LONG)
;
;**********************************************************
CLKSET:
	LD	C,E		;SET UP PARAMETERS
	LD	B,D
	LD	HL,SETENT
CLK2:	LD	A,CALROM


;**********************************************************
;
;	EXECUTE ROM ROUTINE
;	ENTRY-	HL= ENTRY ADDRESS
;		A= ROM #
;	EXIT -	ENTRY ROM RE-SELECTED
;
;**********************************************************
EXROM:
	PUSH	AF		;SAVE NEW ROM

	IN	A,ROMSEL	;SAVE CURRENT ROM
	LD	(ROMSAV),A

	POP	AF		;SELECT NEW ROM
	AND	ROMSMK
	OUT	ROMSEL,A

	PUSH	HL		;SAVE ENTRY

	LD	HL,EXROMR	;PUT RETURN ADDR ON STACK
	EX	(SP),HL
	JP	(HL)		;EXECUTE ROM

EXROMR:	PUSH	AF		;SAVE RETURN VALUE
	LD	A,(ROMSAV)	;RESELECT ORIGINAL ROM
	OUT	ROMSEL,A

	POP	AF		;RETURN VALUE
	RET

  ENDIF
	
	SUBTTL	CHAR I/O ROUTINES
;**************************
;
;	CONSOLE INPUT
;	EXIT -	A= CHAR
;
;**************************
CI:
   IF	USEMON
	CALL	GETMON		;SWITCH IN MONITOR ROM
	JP	0F803H		;USE MONITOR
   ELSE
	CALL	CNSCK		;IF NO CHAR RDY THEN WAIT
	JR	Z,CI
	IN	A,NTD		;ELSE RETURN CHAR
	RET
   ENDIF


;****************************************
;
;	RETURN CONSOLE STATUS
;	EXIT -	A= 0: NOT READY
;		   FFH: CHAR READY
;
;****************************************
CNSCK:
   IF	USEMON
	CALL	GETMON
	JP	0F812H
   ELSE
	IN	A,NTS		;IF DATA NOT READY THEN RETURN 0
	AND	1 SHL NTRDY
TTOST1:	RET	Z
	LD	A,-1		;ELSE RETURN -1
	RET
   ENDIF


;***************************************
;
;	CONSOLE OUTPUT
;	ENTRY-	C= CHAR TO OUTPUT
;
;***************************************
COC:
   IF	USEMON
	CALL	GETMON
	JP	0F809H
   ELSE
	CALL	NTOST		;IF BUSY THEN WAIT
	OR	A
	JR	Z,COC

	LD	A,C
	OUT	NTD,A
	RET


;***********************************************
;
;	RETURN CONSOLE OUTPUT READY STATUS
;	EXIT -	A= 0: BUSY, FFH: READY
;
;***********************************************
NTOST:	IN	A,NTS
	CPL			;REVERSE SENSE
	AND	1 SHL NTBSY
	JR	TTOST1
   ENDIF


;**********************************
;
;	READER DRIVER - DUMMY
;	EXIT -	A= CTRL-Z
;
;**********************************
READER:	LD	A,CTRLZ		;FAKE EOF
	RET


;**************************************
;
;	PUNCH DRIVER
;	ENTRY-	C= CHAR TO OUTPUT
;
;**************************************
PUNCH:	RET


;************************************
;
;	PRINTER DRIVER
;	ENTRY-	C= CHAR TO OUTPUT
;
;************************************
LO:
   IF	USEMON
	CALL	GETMON
	JP	0F80FH
   ELSE
	CALL	LISTST		;IF BUSY THEN WAIT
	JR	Z,LO

	LD	A,C		;OUTPUT CHAR
	SET	7,A
	OUT	CENTOUT,A

	RES	7,A		;OUTPUT LOW TRUE STROBE
	OUT	CENTOUT,A
	SET	7,A
	OUT	CENTOUT,A
	RET
   ENDIF


;*****************************************
;
;	RETURN LIST DEVICE STATUS
;	EXIT -	A= 0: BUSY, FFH:READY
;
;*****************************************
LISTST:
   IF	USEMON
	CALL	GETMON
	JP	0F827H
   ELSE
	IN	A,CENTS		;IF BUSY THEN RETURN 0
	CPL			;INVERT THE SENSE
	AND	1 SHL CENTBSY
	RET	Z

	LD	A,0FFH		;ELSE RETURN -1
	RET
   ENDIF


;****************************
;
;	GET MONITOR PROM SUBR
;	EXIT -	A= ?
;
;****************************
GETMON:
	LD	A,XMONROM
	OUT	(ROMSEL),A
	RET


;**************************
;
;	MESSAGE EDITOR
;
;**************************
EDITOR:	LD	A,(HL)		;MESSAGE EDIT LOOP
	OR	A
	RET	Z
	LD	C,A
	PUSH	HL
	CALL	COC
	POP	HL
	INC	HL
	JR	EDITOR

  IF	INTRPTS
	SUBTTL	INTERRUPTS
;--------------------------------------
;
;	USER INTERRUPT
;
;--------------------------------------
ITRAP:
	PUSH	AF		;SAVE USED REGISTERS
	PUSH	HL
	PUSH	BC

	LD	HL,ITMSG	;NOTIFY USER
IQCONT:	CALL	EDITOR

	LD	HL,IQMSG	;QUERY USER
	CALL	EDITOR
	CALL	CI
	CP	3		;IF CTRL-C THEN WARM BOOT
	JP	Z,0000H

	AND	5FH		;IGNORE CASE

	CP	'Y'		;IF YES THEN ABORT
	JP	Z,0000H

	CP	'I'
	JR	NZ,ITRAP1

	POP	BC		;ELSE RESTORE & GOTO MONITOR TRAP
	POP	HL
	POP	AF
	JP	0038H

ITRAP1:	CP	'M'		;IF MONITOR THEN GOTO MONITOR TRAP
	JR	NZ,ITRAPR

	CALL	GETMON		;INSURE MONITOR THERE
	POP	BC
	POP	HL
	POP	AF
	JP	0F824H

ITRAPR:	POP	BC		;IF CONTINUE THEN RESTORE & RETURN
	POP	HL
	POP	AF
	EI			;RE-ENABLE INTERRUPTS
	RET


;**************************************
;
;	UNSUPPORTED INTERRUPT
;
;**************************************
ILLINT:
	PUSH	AF		;SAVE ALL 8080 REGS
	PUSH	HL
	PUSH	BC
	LD	HL,ILLIM	;NOTIFY USER OF INT
	JR	IQCONT


	SUBTTL	DATA CONSTANTS
;------------------------------------------------
;
;	MODE 2 INTERRUPT VECTOR TABLE
;
;------------------------------------------------
	IF	$ AND 0FFH	;START ON EVEN PAGE BOUNDARY
	DS	100H - ($ AND 0FFH)
	ENDIF
INTABL:
	REPT	7		;1ST 7 ARE UNSUPPORTED
	DW	ILLINT
	ENDM

	DW	ITRAP		;INT 8 IS USER INTERRUPT

  ENDIF

;--------------------------------------
;
;	3740 SECTOR TRANSLATION TABLE
;	**** CP/M SINGLE DENSITY ****
;
;--------------------------------------
SDTRAN:	DB	1,7,13,19,25,5,11,17,23,3,9,15
	DB	21,2,8,14,20,26,6,12,18,24,4,10
	DB	16,22


;--------------------------------------
;
;	DEFAULT DISK PARAMETER BLOCK
;	IBM 3740 SINGLE DENSITY FORMAT
;
;--------------------------------------
SDPBK:	DW	26		;SECTORS PER TRACK
	DB	3		;BLOCK SHIFT FACTOR
	DB	7		;BLOCK MASK
	DB	0		;NULL MASK
	DW	242		;DISK SIZE -1
	DW	63		;DIRECTORY MAX
	DB	11000000B	;ALLOC 0
	DB	0		;ALLOC 1
	DW	16		;CHECK SIZE
	DW	2		;TRACK OFFSET


;---------------------------------
;
;	HARD DISK DATA
;
;---------------------------------
IOPB:	REPT	16		;;HARD DISK IOPB
	DB	0
	ENDM

IOPBADR:
	DB	LOW IOPB	;HARD DISK IOPB POINTER TABLE
	DB	HIOPBL
	DB	HIGH IOPB
	DB	HIOPBH
	DB	0
	DB	HIOPBX

LOGIOPB:
	DB	LOGCMD		;READ COMMAND
	DB	4		;DRIVE
	DW	0		;TRACK
	DW	1		;SECTOR
	DB	0		;FLAGS (LOGON)
	DW	DEFBFR		;DMA ADDR
	DB	0		;BANK ADDR
	DS	(LOGIOPB + 16) - $

LIOPBAD:
	DB	LOW LOGIOPB	;LOGON DISK IOPB POINTER TABLE
	DB	HIOPBL
	DB	HIGH LOGIOPB
	DB	HIOPBH
	DB	0
	DB	HIOPBX
	


;------------------
;
;   MESSAGES
;
;------------------
MSGLE:	DB	CR,LF,'LOAD ERROR',0
   IF	INTCPTS
ISCMSG:	DB	CR,LF,'ILL. SYS. CALL',CR,LF,0
   ENDIF
   IF	INTRPTS
ITMSG	DB	CR,LF,'User',0
ILLIM	DB	CR,LF,'Unsupported',0
IQMSG	DB	' Interrupt: Abort? (Y/N) - ',0
   ENDIF

;----------------------------
;
;	ID SECTOR LABEL
;
;----------------------------
JADEID:	DB	'Jade DD '
IDSZE:	EQU	$-JADEID


;--------------------------------------
;
;	DRIVE PARAMETER HEADER AREA
;	1 PER DRIVE
;
;--------------------------------------
HDDPH0:	DW	0		;SECTOR TRAN TBL (OR 0 IF NO XLATE)
	DW	0		;SCRATCH AREA
	DW	0		;"
	DW	0		;"
	DW	DIRBF		;DIRECTORY BUFFER PTR
	DW	HDDPB		;DRIVE PARAMETER BLK PTR
	DW	0		;NO DRIVE DISK CHECKSUMS
	DW	HDALL0		;DRIVE CLUSTER ALLOCATION BIT MAP PTR

HDDPH1:	DW	0		;SECTOR TRAN TBL (OR 0 IF NO XLATE)
	DW	0		;SCRATCH AREA
	DW	0		;"
	DW	0		;"
	DW	DIRBF		;DIRECTORY BUFFER PTR
	DW	HDDPB		;DRIVE PARAMETER BLK PTR
	DW	0		;NO DRIVE DISK CHECKSUMS
	DW	HDALL1		;DRIVE CLUSTER ALLOCATION BIT MAP PTR


D0DPH:	DW	0		;SECTOR TRAN TBL (OR 0 IF NO XLATE)
	DW	0		;SCRATCH AREA
	DW	0		;"
	DW	0		;"
	DW	DIRBF		;DIRECTORY BUFFER PTR
	DW	D0DPB		;DRIVE PARAMETER BLK PTR
	DW	D0CHK		;DRIVE DISK CHECKSUMS ARRAY PTR
	DW	D0ALL		;DRIVE CLUSTER ALLOCATION BIT MAP PTR

   IF	NDRVS GT 3
D1DPH:	DW	0
	DW	0
	DW	0
	DW	0
	DW	DIRBF
	DW	D1DPB
	DW	D1CHK
	DW	D1ALL
   ENDIF

   IF	NDRVS GT 4
D2DPH:	DW	0
	DW	0
	DW	0
	DW	0
	DW	DIRBF
	DW	D2DPB
	DW	D2CHK
	DW	D2ALL
   ENDIF

   IF	NDRVS GT 5
D3DPH:	DW	0
	DW	0
	DW	0
	DW	0
	DW	DIRBF
	DW	D3DPB
	DW	D3CHK
	DW	D3ALL
   ENDIF

;---------------------------------
;
;	HARD DISK PARAMETER BLOCKS
;
;---------------------------------
HDDPB:	DW	128		;SECTORS PER TRACK (LOGICAL)	(SPT)
	DB	5		;BLOCK SHIFT FACTOR		(BSH)
	DB	31		;BLOCK MASK			(BLM)
	DB	1		;NULL MASK			(EXM)
	DW	1015		;DISK SIZE (CLUSTERS -1)	(DSM)
	DW	1152 / 2	;DIRECTORY MAX			(DRM)
	DB	0FFH		;ALLOCATION 0			(AL0)
	DB	10000000B	;ALLOCATION 1			(AL1)
	DW	0		;CHECK SIZE			(CKS)
	DW	2		;TRACK OFFSET			(OFF)


BIOSND	EQU	$
	SUBTTL	DATA AREA
;------------------------------------------------
;
;	THE REMAINING AREA DOES NOT HAVE TO
;  BELONG ON THE DISK.
;
;------------------------------------------------
;
;   DRIVE ALLOCATION AREAS DECLARED
;
;------------------------------------------------

D0ALL:	DS	ALLSIZ	;DISK CLUSTER ALLOCATION BIT MAP
D0CHK	DS	CHKSIZ	;DIRECTORY CHECKSUMS STORAGE (1 BYTE PER DIR SECTOR)

   IF	NDRVS GT 3
D1ALL:	DS	ALLSIZ
D1CHK	DS	CHKSIZ
   ENDIF

   IF	NDRVS GT 4
D2ALL:	DS	ALLSIZ
D2CHK	DS	CHKSIZ
   ENDIF

   IF	NDRVS GT 5
D3ALL:	DS	ALLSIZ
D3CHK	DS	CHKSIZ
   ENDIF

   IF	INTCPTS
;----------------------------
;
;	CLOCK BUFFER
;
;----------------------------
CLKBFR:
	DS	13

ROMSAV	DS	1	;ROM SWAP SAVE OF ORIGINAL ROM


   ENDIF
;----------------------------
;
;	HARD DISK ALLOCATION
;
;----------------------------
HDALL0:	DS	128
HDALL1:	DS	128

   IF	($ > 0F800H) OR ($ < 8000H)
	CONMSG	BIOS TOO BIG
   ENDIF

	END