MEMORY	{
	DF_stack:	origin	= 0xF0000000,	length	=   0x01000
	KV_loadsite:    origin  = 0xF0010000,   length  =  0x7f0000
	KV_windows:	origin	= 0xF7400000,	length  =  0x100000
	KV_sysseg:	origin  = 0xF1000000,	length 	=  0x6400000
	KV_pioseg:	origin  = 0xF7800000,	length 	=  0x400000
	KV_crllry:	origin  = 0xF7C00000,	length 	=  0x400000
	UV_ublock:	origin  = 0xe0000000,	length =    0x20000
	UV_stack:       origin  = 0x7ffffffc,   length =    0x00000
	}
SECTIONS {
	BKI (COPY): { . += 2; } = 2	
	
	dft_stack (NOLOAD):
		{
		df_stack	=	.;
		} > DF_stack
	page0 0xF0000000 (NOLOAD):
		{
		bootinfo = .+0x800;
		kspt0 = .+0x1000;
		kpd0 = .+0x2000;
		kspt1 = .+0x3000;
		}
	.text:	{
		stext = .;
		../pack.d/kernel/start.o(.text)
		} > KV_loadsite
	.data ALIGN(0x1000) :	{
		sdata = .;
		../pack.d/kernel/locore.o(.data)
		} > KV_loadsite
	.bss ALIGN(0x1000) :	{
		sbss = .;
		vm_dmabuffer = .;	
		. += 0x2400;
		vm_dma_end = .;
		../pack.d/kernel/locore.o(.bss)
		} > KV_loadsite
	kv_sysseg (NOLOAD):
		{
		syssegs		=	.;
		} > KV_sysseg
	kv_windows (NOLOAD):
		{
		win_ublk	=	.;
		win_ublk2	=	.+0x80000;
		} > KV_windows
	kv_pioseg (NOLOAD):
		{
		piosegs		=	.;
		} > KV_pioseg
	kv_crllry (NOLOAD):
		{
		processor	=	.; . += 4;
		processor_index	=	.; . += 4;
		processor_owner	=	.; . += 4;
		processor_bit	=	.; . += 4;
		ipl		=	.; . += 4;
		iplmask		=	.; . += 16;
		curmask		=	.; . += 2;
		masterline	=	.; . += 2;
		fp_proc		=	.; . += 4;
		lockbstack	=	.; . += 4;
		lockbp		=	.; . += 4;
		prt_where	=	.; . += 2;
		fp_kind		=	.; . += 1;
		weitek_kind	=	.; . += 1;
		weitek_proc	=	.; . += 4;
		curproc		=	.; . += 4;
		old_curproc	=	.; . += 4;
		oldproc		=	.; . += 4;
		sip		=	.; . += 4;
		curpri		=	.; . += 4;
		switching	=	.; . += 4;
		panic_level	=	.; . += 4;
		panicstr	=	.; . += 4;
		runrun		=	.; . += 1;
		activeintr	=	.; . += 1;
		v86procflag	=	.; . += 1;
		prt_prefix	=	.; . += 1;
		prt_nl		=	.; . += 1;
		ShareUse387	=	.; . += 1;
		modified_upage	=	.; . += 1;
		cpu_family	=	.; . += 1;
		vuifill		=	.; . += 2;
		lticks		=	.; . += 4;
		dotimein	=	.; . += 4;
		idleproc	=	.; . += 4;
		usertable	=	.; . += 4;
		eipsave		=	.; . += 4;
		nodispatch	=	.; . += 4;
		was_fvectintr	=	.; . += 4;
		cflush		=	.; . += 4;
		cur_eproc	=	.; . += 4;
		freereg_page	=	.; . += 4;
		jtssel		=	.; . += 4;
		gdtp		=	.; . += 4;
		idtp		=	.; . += 4;
		ivectp		=	.; . += 4;
		canonbp		=	.; . += 4;
		picipl		=	.; . += 4;
		pdf		=	.; . += 4;
		ciha_addr	=	.; . += 4;
		sc_io		=	.; . += 4;
		sc_iobase	=	.; . += 4;
		sc_rambase	=	.; . += 4;
		smp_nmip	=	.; . += 4;
		c_intrc		= 	.; . += 4;
		c_minfo		= 	.; . += 4;
		c_extinfo	= 	.; . += 4;
		c_sysinfo	= 	.; . += 4;
		cpu_id		=	.; . += 4;
		cpu_features	=	.; . += 4;
		crllry_info	=	.; . += 4;
		
		} > KV_crllry
	uv_stack (NOLOAD):
		{
		userstack	=	.;
		} > UV_stack
	uv_ublock (NOLOAD):
		{
		u		=	.;
		} > UV_ublock
	}
